A4

A4 — Fixe la fréquence de base pour le la du diapasion.

Description

Ces instructions sont des affectations de valeurs globales réalisées au début d'un orchestre, avant que tout bloc d'instrument ne soit défini. Leur fonction est de fixer certaines variables dont le nom est un mot réservé et qui sont nécessaires à l'exécution. Une fois fixés, ces mots réservés peuvent être utilisés dans des expressions n'importe où dans l'orchestre.

Syntaxe

A4 = iarg

Initialisation

A4 = (facultatif) -- fixe la fréquence de référence pour la hauteur A4 (la du diapason) à iarg Hz. La valeur par défaut est 440.

De plus, toute variable globale peut être initialisée par une instruction de la période d'initialisation n'importe où avant la première instruction instr. Toutes les affectations ci-dessus sont exécutées dans l'instrument 0 (passe-i seulement) au début de l'exécution réelle.

A partie de la version 6.08 de Csound version 6.08, A4 peut être utilisée. Elle affecte le comportement des opcodes cpspch, cpsoct, cps2pch, cpsxpch et cpsmidinn.

Exemples

Voici un exemple de l'opcode A4. Il utilise le fichier A4.csd.

Exemple 34. Exemple de l'opcode A4.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
; For Non-realtime ouput leave only the line below:
; -o A4.wav -W ;;; for file output any platform

; By Stefano Cucchi - 2020

</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

#define STANDARDPITCH #440# ; as set by ISO 1975:16 - STANDARD MUSICAL PITCH
#define BAROQUEPITCH #415# ; common use (but not standard) in Baroque era (1600 - 1750) 
#define HIGHER #443# ; some orchestras, mainly in Europe use higher pitch (442-443 Hz)

#define EXPRESSION #(440*1.3)+200# ; you can use an expression

A4 = $STANDARDPITCH
;A4 = $BAROQUEPITCH
;A4 = $HIGHER

;A4 = $EXPRESSION

instr 1	
  
ipch =	p4
icps =	cpspch(ipch)
asig	oscil 0.7, icps, 1
	outs  asig, asig

endin

</CsInstruments>
<CsScore>

f 1 0 4096 10 1 0.3 0.2. 0.1

; Theme from Bach BWV 578 -  Little fugue in G minor.
i 1 0 1 7.07
i 1 + 1 8.02
i 1 + 1.5 7.10
i 1 + .5 7.09
i 1 + .5 7.07
i 1 + .5 7.10
i 1 + .5 7.09
i 1 + .5 7.07
i 1 + .5 7.06
i 1 + .5 7.09
i 1 + 1 7.02
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

sr, kr, ksmps, nchnls, nchnls_i, 0dbfs, cpspch, cpsoct, cpsmidinn, cps2pch, cpsxpch.

Crédits

Auteur : John ffitch
Septembre 2016

Nouveau dans la version 6.08 de Csound.