balance

balance — Ajuste un signal audio selon les valeurs d'un autre.

Description

La valeur efficace de asig peut être interrogée, fixée ou ajustée pour s'adapter à celle d'un signal de comparaison.

Syntaxe

ares balance asig, acomp [, ihp] [, iskip]

Initialisation

ihp (facultatif) -- point à mi-puissance (en Hz) d'un filtre passe-bas interne spécial. La valeur par défaut est 10.

iskip (facultatif, 0 par défaut) -- disposition initiale de l'espace de données interne (voir reson). La valeur par défaut est 0.

Exécution

asig -- signal audio en entrée

acomp -- le signal de comparaison

balance restitue une version de asig, dont l'amplitude a été modifiée de façon à ce que sa valeur efficace soit égale à celle d'un signal de comparaison acomp. Ainsi un signal qui a subi une perte de puissance (par exemple en traversant un banc de filtres) peut être restauré en l'ajustant, par exemple, à sa propre source. Il faut noter que gain et balance n'effectuent que des modifications d'amplitude, les signaux de sortie ne subissant aucune autre altération.

Exemples

Voici un exemple de l'opcode balance. Il utilise le fichier balance.csd.

Exemple 87. Exemple de l'opcode balance.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o balance.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1
; Generate a band-limited pulse train.
asrc buzz 0.9, 440, sr/440, 1

; Send the source signal through 2 filters.
a1 reson asrc, 1000, 100       
a2 reson a1, 3000, 500

; Balance the filtered signal with the source.
afin balance a2, asrc
     outs afin, afin

endin

</CsInstruments>
<CsScore>
;sine wave.
f 1 0 16384 10 1

i 1 0 2
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

balance2, gain, rms