Description

Implémentation d'un filtre de Butterworth passe-haut du second ordre. Cet opcode peut aussi être écrit comme buthp.

Syntaxe

ares butterhp asig, kfreq [, iskip]

ares butterhp asig, afreq [, iskip]

Initialisation

iskip (facultatif, 0 par défaut) -- L'initialisation est ignorée s'il est présent et non nul.

Exécution

Ces filtres sont des filtres RII de Butterworth du second ordre. Ils sont légèrement plus lents que les filtres originaux de Csound, mais ils offrent une bande passante presque plate et une précision et une atténuation de la bande bloquée très bonnes.

asig -- Signal d'entrée à filtrer.

kfreq -- Fréquence de coupure ou centrale pour chacun des filtres.

Exemples

Voici un exemple de l'opcode butterhp. Il utilise le fichier butterhp.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o butterhp.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1	  ; White noise 

asig rand 0.5
outs asig, asig

endin

instr 2	; filtered noise

asig rand 0.6
ahp  butterhp asig, 500  ;pass frequencies above 500 Hz
     outs ahp, ahp

endin

</CsInstruments>
<CsScore>

i 1 0 2
i 2 2.5 2
e

</CsScore>
</CsoundSynthesizer>

Voir aussi

butterbp, butterbr, butterlp

Crédits

Existait dans la version 3.30

Paramètres de taux audio introduits dans la version 6.02

Octobre 2013.