dssictls

dssictls — Envoie une information de contrôle à un greffon LADSPA ou DSSI.

[Note] Note
Greffon : nécessite le greffon dssi4cs

Syntaxe

dssictls ihandle, iport, kvalue, ktrigger 

Description

Opcode du greffon dssi4cs.

dssictls envoie des valeurs de contrôle sur le port de contrôle d'un greffon.

Initialisation

ihandle - le numéro qui identifie le greffon, généré par dssiinit.

iport - numéro du port de contrôle

Exécution

kvalue - valeur à assigner au port.

ktrigger - détermine si l'information de contrôle doit être envoyée (ktrigger = 1) ou non. Utile pour réduire l'information de contrôle, si l'on génère ktrigger avec metro.

dssictls envoie de l'information de contrôle sur le port de contrôle d'un greffon LADSPA ou DSSI. Les ports de contrôle valides et les valeurs autorisées sont donnés par dssiinit. Si l'on utilise des valeurs hors limite, il peut y avoir un comportement indéfini.

Exemples

Voici un exemple de l'opcode dssictls. Il utilise le fichier dssictls.csd.

Exemple 250. Exemple de l'opcode dssictls.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o dssictls.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2

gihandle dssiinit "caps.so", 1, 1	; = equaliser and
gaoutl init  0				; verbose about all ports
gaoutr init  0

instr 1	; activate DSSI

dssiactivate gihandle, 1
endin

instr 2
ain1	diskin2 "beats.wav", 1,0,1	; loop

gaoutl = gaoutl+(ain1*.1)		; temper input
gaoutr = gaoutr+(ain1*.1)
endin

instr 3

dssictls gihandle, 2, -48, 1	; 31 Hz range -48 to 24
dssictls gihandle, 3, -48, 1	; 63 Hz range -48 to 24
dssictls gihandle, 4, -48, 1	; 125 Hz range -48 to 24
dssictls gihandle, 5, 20, 1	; 250 Hz range -48 to 24
dssictls gihandle, 6, -48, 1	; 500 Hz range -48 to 24
dssictls gihandle, 7, -48, 1	; 1 kHz Hz range -48 to 24
dssictls gihandle, 8, -48, 1	; 2 kHz range -48 to 24
dssictls gihandle, 9, 24, 1	; 4 kHz range -48 to 24
dssictls gihandle, 10, 24, 1	; 8 kHz range -48 to 24
dssictls gihandle, 11, 24, 1	; 16 kHz range -48 to 24

endin

instr 4

aout1, aout2	dssiaudio gihandle, gaoutl, gaoutr	;get beats.wav, mono out
		outs aout1,aout2

gaoutl = 0
gaoutr = 0
endin

</CsInstruments>
<CsScore>
i 1 0 20 
i 2 1 20
i 3 1 20
i 4 0 20

e
</CsScore>
</CsoundSynthesizer>


Crédits

2005

Par Andrés Cabrera

Utilise du code provenant du sdk de LADSPA par Richard Furse.