framebuffer

framebuffer — Lit des signaux audio dans des tableaux unidimensionnels de taux-k et vice versa avec une taille de tampon donnée.

Description

Opcode du greffon framebuffer.

framebuffer convertit des signaux audio dans un tableau unidimensionnel de taux-k de taille donnée. La taille du tableau de taux-k doit être supérieure à ksmps. Il convertit aussi les tableaux unidimensionnels de taux-k en signaux audio, les tableaux de taux-k ne doivent pas être initialisés et avoir une taille supérieure à ksmps. Le tampon est circulaire et peut être utilisé pour du traitement audio à base de trames comme l'analyse/resynthèse spectrale ou comme une simple ligne à retard.

Syntaxe

kout[] framebuffer ain, isize
aout framebuffer kin, isize

Initialisation

isize -- La quantité d'échantillons contenus dans le tampon.

Exécution

kout[] -- Le tableau de taux-k en sortie. ain -- Le signal audio en entrée.

aout -- Le signal audio en sortie. kin -- Le tableau de taux-k en entrée.

Exemples

Voici un exemple simple de l'opcode frambuffer. Il utilise le fichier framebuffer.csd.

Exemple 381. Exemple de l'opcode frambuffer.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-odac
</CsOptions>
<CsInstruments>
nchnls = 2
0dbfs = 1
ksmps = 128
sr = 44100

instr 1
    isize init 1024
    ioverlaps init 4

    asig diskin2 "fox.wav", 1, 0, 1
    kframe[] framebuffer asig, isize
    kwindowedFrame[] window kframe, isize

    aout olabuffer kwindowedFrame, ioverlaps
    aout = aout / 2

    outs aout, aout
endin

</CsInstruments>
<CsScore>
i 1 0 400
</CsScore>
</CsoundSynthesizer>


Voir aussi

olabuffer shiftin shiftout

Crédits

Auteur : Edward Costello;
NUIM, 2015

Nouveau dans la version 6.06