Description

Efface une table de fonction.

Syntaxe

ftfree ifno, iwhen

Initialisation

ifno -- le numéro de la table à effacer.

iwhen -- s'il vaut zéro, la table est effacée pendant la période d'initialisation ; sinon le numéro de table est enregistré pour que celle-ci soit effacée lors de la désactivation de la note.

	Note
	Si la table est effacée durant une initialisation, il est possible qu'un opcode antérieur utilisant la table échoue ou se plante pendant un cycle d'exécution. Il est de la responsabilité de l'utilisateur d'éviter cette erreur.

Exemples

Voici un exemple de l'opcode ftfree. Il utilise le fichier ftfree.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o ftfree.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gitempTable ftgen 0, 0, 65537, 10, 1

instr 1

aout oscili .5, 440, gitempTable
     outs aout, aout

;free temp table at deinit time
ftfree gitempTable, 1
print  gitempTable

endin
</CsInstruments>
<CsScore>
f 0 5

i 1 0 .1
i 1 3 1

e
</CsScore>
</CsoundSynthesizer>

instr 1:  gitempTable = 101.000
B  0.000 ..  3.000 T  3.000 TT  3.000 M:  0.50000  0.50000
INIT ERROR in instr 1: Invalid ftable no. 101.000000
instr 1:  gitempTable = 101.000
Error deleting ftable 101
    B  3.000 - note deleted.  i1 had 1 init errors
B  3.000 ..  5.000 T  5.000 TT  5.000 M:  0.00000  0.00000

Crédits