Description

Retourne la date du début de boucle d'une table de fonction en mémoire.

Syntaxe

ftlptim(x) (arg de taux-i seulement)

Exécution

Retourne la date du début de boucle (en secondes) de la table de fonction numéro x. La valeur retournée est la durée de l'attaque et du decay directement enregistrés avant le segment de boucle. Retourne zéro (et un message d'avertissement) si l'échantillon ne contient pas de points de boucle.

Exemples

Voici un exemple de l'opcode ftlptim. Il utilise les fichiers ftlptim.csd et Church.wav.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o ftlptim.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs   =1

instr 1

itim = ftlptim(1)
     print itim
aout loscil3 .8, 40, 1
     outs aout, aout

endin
</CsInstruments>
<CsScore>
f 1 0 0 1 "Church.wav" 0 0 0 ;Csound computes tablesize

i 1 0 5
e
</CsScore>
</CsoundSynthesizer>

Le fichier audio « Church.wav » contenant une boucle, la sortie comprendra des lignes comme celles-ci :

Base Note : 60	Detune    : 0
Low  Note : 0	High Note : 127
Low  Vel. : 0	High Vel. : 127
Gain      : 1	Count     : 1
mode      : 801
start     : 4529	end       : 4912	count  :0
mode      : 0
start     : 0	end       : 0	count  :0

Voir aussi

ftchnls, ftlen, ftsr, nsamp

Crédits