Description

mididefault est conçu pour simplifier l'écriture d'instruments que l'on peut utiliser de manière interchangeable avec une partition ou depuis l'entrée MIDI, et pour faciliter l'adaptation d'instruments écrits à l'origine pour une partition au fonctionnement à partir d'une entrée MIDI.

En général, il doit être possible d'écrire des définitions d'instrument qui fonctionnent de la même manière avec une partition et avec le MIDI, que ce soit un fichier MIDI ou une entrée MIDI en , sans utiliser d'instructions conditionnelles supplémentaires, et qui tirent pleinement avantage des messages de voix MIDI.

Noter que la liaison entre des intruments de Csound et les numéros de canal MIDI se fait en utilisant l'opcode massign lors d'une exécution en . Pour les exécutions de fichier MIDI, les numéros d'instruments sont liés par défaut au canal MIDI + 1, mais ces valeurs par défaut peuvent être modifiées par tout message de changement de programme dans le fichier.

Syntaxe

mididefault xdefault, xvalue

Exécution

xdefault -- spécifie une valeur par défaut qui sera utilisée pendant l'activation MIDI.

xvalue -- remplacé par xdefault durant l'activation MIDI, reste inchangé dans les autres cas.

Si l'instrument a été activé par une entrée MIDI, l'opcode remplace la valeur de xvalue par celle de xdefault. Si l'instrument n'a PAS été activé par une entrée MIDI, la valeur de xvalue reste inchangée.

Grâce à cela, les p-champs de la partition peuvent recevoir une valeur par défaut durant l'activation MIDI, et une valeur de la partition dans les autres cas.

	Adaptation d'un instrument de Csound activé par partition.
	Voir la section Opcodes pour l'Interopérabilité MIDI/Partition pour plus de détails sur l'adaptation d'instruments pilotés par partition au MIDI et vice-versa.

Exemples

Voici un exemple de l'opcode mididefault. Il utilise le fichier mididefault.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    -M1  ;;;realtime audio out and midi in 
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o mididefault.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

mididefault 60, p3					;ensures that a MIDI-activated instrument will have a positive p3 field
midinoteoncps p4, p5					;puts MIDI key translated to cycles per second into p4, and MIDI velocity into p5

kvel = p5/127						;scale midi velocity to 0-1
kenv madsr 0.5, 0.8, 0.8, 0.5				;amplitude envelope multiplied by
asig pluck kenv*kvel, p4, p4, 2, 1			;velocity		
     outs  asig, asig

endin
</CsInstruments>
<CsScore>
f 0 30	;runs for 30 seconds
f 2 0 4096 10 1	

i 1 0 2 440 100	; play these notes from score as well
i 1 + 2 1440 100
e

</CsScore>
</CsoundSynthesizer>

Voir aussi

midichannelaftertouch, midicontrolchange, midinoteoff, midinoteoncps, midinoteonkey, midinoteonoct, midinoteonpch, midipitchbend, midipolyaftertouch, midiprogramchange

Crédits

Auteur : Michael Gogins

Nouveau dans la version 4.20