printks2

printks2 — Imprime une nouvelle valeur à chaque changement d'une variable de contrôle, en utilisant une syntaxe à la printf().

Description

Imprime une nouvelle valeur à chaque changement d'une variable de contrôle, en utilisant une syntaxe à la printf().

Syntaxe

printks2 "string", kval

Initialisation

"string" -- la chaîne de caractère indiquant le format.

Exécution

kval -- signal à imprimer. Le style de l'impression est spécifié dans « string » avec les spécificateurs standard du C (%f, %d, etc.).

Formatage de l'impression

On peut utiliser tous les caractères de contrôle standard de printf() du langage C. Par exemple, si kval = 153.26789 quelques options de formatage sont :

  1. %f imprime en pleine précision : 153.26789

  2. %5.2f imprime : 153.26

  3. %d imprime seulement des entiers : 153

  4. %c traite kval comme un code de caractère ASCII.

En plus de tous les codes de printf(), printks2 supporte ces codes de caractère utiles :

Code de printks2 Code de caractère
\\r, \\R, %r ou %R Retour chariot (\r)
\\n, \\N, %n, %N Caractère de nouvelle ligne (\n)
\\t, \\T, %t, or %T Tabulation (\t)
%! point-virgule (;) Nécessaire car un « ; » est interprété comme un commentaire.
^ Caractère d'échappement (0x1B)
^ ^ Accent circonflexe (^)
˜ ESC[ (escape+[ est la séquence d'échappement pour les consoles ANSI)
˜˜ tilde (˜)

Pour plus d'information sur le formatage de printf(), consulter une documentation sur le langage C.

Exemples

Voici un exemple de l'opcode printks2. Il utilise le fichier printks2.csd.

Exemple 787. Exemple de l'opcode printks2.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
; For Non-realtime ouput leave only the line below:
; -o printk.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; Initialize the global variables.
sr = 44100
kr = 44100
ksmps = 1
nchnls = 1

; Instrument #1.
instr 1
  ; Change a value linearly from 0 to 100,
  ; over the period defined by p3.
  kval line 0, p3, 100

  ; Print the value of kval when it changes.
  printks2 "value now %f\n", int(kval)
endin


</CsInstruments>
<CsScore>

; Play Instrument #1 for 5 seconds.
i 1 0 5
e


</CsScore>
</CsoundSynthesizer>


Voir aussi

printk2 and printk2 and printk

Crédits

Auteur : John ffitch
Bath, UK
Mars 2014

Nouveau dans la version 6.03 de Csound.