product

product — Multiplie n'importe quel nombre de signaux de taux-a.

Description

Multiplie n'importe quel nombre de signaux de taux-a.

Syntaxe

ares product asig1, asig2 [, asig3] [...]

Exécution

asig1, asig2, asig3, ... -- signaux de taux-a à multiplier.

Exemples

Voici un exemple de l'opcode product. Il utilise le fichier product.csd.

Exemple 792. Exemple de l'opcode product.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o product.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gisine ftgen 0, 0, 2^10, 10, 1

instr 1

a1   oscili 1, 10.0, gisine		;combine 3 sinusses
a2   oscili 1, 1.0, gisine		;at different rates
a3   oscili 1, 3.0, gisine
ares product a1, a2, a3

ares = ares*10000			;scale result and
asig poscil .5, ares+110, gisine	;add to frequency			
     outs asig, asig

endin
</CsInstruments>
<CsScore>

i1 0 5
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Gabriel Maldonado
Italie
Avril 1999

Nouveau dans la version 3.54 de Csound