Description

Prend la moyenne des fonctions temporelles amp/fréq de chaque canal d'analyse sur une durée spécifiée (tronquée au nombre de trames). Il y a un effet de bord : le flot pvoc en entrée est retardé de cette durée.

Syntaxe

fsig pvsblur fsigin, kblurtime, imaxdel

Exécution

fsig -- flot pv de sortie

fsigin -- flot pv d'entrée

kblurtime -- durée en secondes pendant laquelle les valeurs moyennes des fenêtres seront prises.

imaxdel -- retard maximum, utilisé pour allouer la mémoire utilisée dans le calcul de la moyenne.

Cet opcode estompe un flot pvs en lissant les fonctions temporelles d'amplitude et fréquence (une sorte de filtrage passe-bas) ; l'importance de cet effet dépend de la longueur de la période sur laquelle est prise la moyenne, de plus grandes périodes donnant un effet plus prononcé.

	Avertissement
	Il est dangereux d'utiliser la même variable-f à la fois comme entrée et comme sortie des opcodes pvs. Ceci peut produire un comportement indéfini de certains de ces opcodes. Utilisez une variable différente à gauche et à droite de l'opcode.

Exemples

Voici un exemple de l'opcode pvsblur. Il utilise le fichier pvsblur.csd.

 <CsoundSynthesizer>
 <CsOptions>
 ; Select audio/midi flags here according to platform
 ; Audio out   Audio in
 -odac       ;;;RT audio out
 ; For Non-realtime ouput leave only the line below:
 ; -o pvsblur.wav -W ;;; for file output any platform
 </CsOptions>
 <CsInstruments>

 sr = 44100
 ksmps = 32
 nchnls = 2
 0dbfs  = 1

 ;; example written by joachim heintz 2009

 instr 1
 ifftsize	= 1024
 ioverlap	= ifftsize / 4
 iwinsize	= ifftsize
 iwinshape	= 1               ; von-Hann window
 Sfile	= "fox.wav"
 ain		soundin	Sfile
 fftin	pvsanal	ain, ifftsize, ioverlap, iwinsize, iwinshape; fft-analysis of the audio-signal
 fftblur	pvsblur	fftin, p4, 1; blur
 aout		pvsynth	fftblur; resynthesis
 		outs	aout, aout
 endin

 </CsInstruments>
 <CsScore>
 i 1 0 3    0
 i 1 3 3   .1
 i 1 6 3.5 .5
 e
 </CsScore>
 </CsoundSynthesizer>

Voir aussi

pvsanal, pvsynth, pvsadsyn

Crédits

Nouveau greffon dans la version 5

Novembre 2004.