Description

Retourne la racine carrée de x (x non-negatif).

Les valeurs de l'argument sont restreintes pour log, log10 et sqrt.

Syntaxe

sqrt(x) (pas de restriction de taux)

sqrt(k/i[]) (k- ou i-tableau)

où l'argument entre parenthèses peut être une expression. Les convertisseurs de valeur effectuent une transformation arithmétique d'unités d'une sorte en unités d'une autre sorte. Le résultat peut devenir ensuite un terme dans une autre expression.

Exemples

Voici un exemple de l'opcode sqrt. Il utilise le fichier sqrt.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sqrt.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100 
ksmps = 32 
0dbfs  = 1 
nchnls = 2

instr 1

asig   pluck 0.7, 55, 55, 0, 1
kpan   line 0,p3,1 
kleft  = sqrt(1-kpan) 
kright = sqrt(kpan) 
printks "square root of left channel = %f\\n", 1, kleft	;show coarse of sqaure root values
       outs asig*kleft, asig*kright					;where 0.707126 is between 2 speakers

endin 
</CsInstruments>
<CsScore>

i 1 0 10
e
</CsScore>
</CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

square root of left channel = 1.000000\r
square root of left channel = 0.948688
square root of left channel = 0.894437
square root of left channel = 0.836676
square root of left channel = 0.774620
square root of left channel = 0.707139
square root of left channel = 0.632499
square root of left channel = 0.547781
square root of left channel = 0.447295
square root of left channel = 0.316242

Voir aussi

abs, exp, frac, int, log, log10, i