trlowest

trlowest — Extracts the lowest-frequency track from a streaming track input signal.

Description

The trlowest opcode takes an input containg TRACKS pv streaming signals (as generated, for instance by partials) and outputs only the lowest track. In addition it outputs two k-rate signals, corresponding to the frequency and amplitude of the lowest track signal.

Syntax

fsig, kfr, kamp trlowest fin1, kscal

Performance

fsig -- output pv stream in TRACKS format

kfr -- frequency (in Hz) of the lowest-frequency track

kamp -- amplitude of the lowest-frequency track

fin -- input pv stream in TRACKS format.

kscal -- amplitude scaling of output.

Examples

Here is an example of the trlowest opcode. It uses the file trlowest.csd.

Example 1126. Example of the trlowest opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o trlowest.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

ain     diskin2 "beats.wav", 1
fs1,fsi2 pvsifd ain, 2048, 512, 1	; ifd analysis
fst partials fs1, fsi2, .003, 1, 3, 500 ; partial tracking
flow,kfr,kamp trlowest fst, 1		; lowest freq-track 
aout	tradsyn	flow, 1, 1, 1, 1	; resynthesis of lowest frequency
	outs	aout*2, aout*2

endin
</CsInstruments>
<CsScore>
f1 0 8192 10 1	;sine wave

i 1 0 3
e
</CsScore>
</CsoundSynthesizer>


The example above shows partial tracking of an ifd-analysis signal, extraction of the lowest frequency and resynthesis.

Credits

Author: Victor Lazzarini
February 2006

New in Csound 5.01