Description

ATSinterpread permet de déterminer l'enveloppe de fréquence de n'importe quel ATSbufread.

Syntaxe

kamp ATSinterpread kfreq

Exécution

kfreq - une valeur de fréquence (en Hz) utilisée par ATSinterpread comme indice dans la table produite par un ATSbufread.

ATSinterpread prend une valeur de fréquence (kfreq en Hz). Cette fréquence sert à indexer les données d'un ATSbufread. La valeur retournée est une amplitude obtenue de l'ATSbufread après interpolation. ATSinterpread permet de déterminer l'enveloppe de fréquence de n'importe quel ATSbufread. Ces données peuvent être utiles pour plusieurs raisons, dont l'une est la réalisation de la synthèse croisée entre des données provenant d'un fichier ATS et des données non ATS.

Exemples

Voici un exemple de l'opcode ATSinterpread. Il utilise le fichier ATSinterpread.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc for RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o ATSinterpread.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

; by Menno Knevel - 2021

ires system_i 1,{{ atsa fox.wav fox.ats }} ; ATSA wants a mono file!

instr 1	

ktime	line	0, p3, 2.65
	ATSbufread ktime, 1, "fox.ats", p4
kamp	ATSinterpread 	p5  ; get envelope from partial
aosc	poscil3	kamp, p5
	outs	aosc * 8, aosc * 8

endin

</CsInstruments>
<CsScore>
;              partial     index         
s
i 1 0 2.65      12          1000
i 1 3 2.65      12          150
i 1 6 2.65      12          10000
s
i 1 0 2.65      72          1000
i 1 3 2.65      72          150
i 1 6 2.65      72          10000
e
</CsScore>
</CsoundSynthesizer>

Cet exemple montre comment utiliser ATSinterpread. Ici une fréquence est fournie par la partition (p5) et cette fréquence est passée à un ATSinterpread (avec un ATSbufread) correspondant. L'ATSinterpread utilise cette fréquence pour retourner l'amplitude correspondante basée sur le fichier ATS donné par le ATSbufread (beats.ats dans ce cas). Nous utilisons ensuite cette amplitude pour pondérer une onde sinus qui est synthétisée avec la même fréquence (p5). On peut étendre ceci pour inclure plusieurs ondes sinus. De cette manière il est possible de synthétiser n'importe quelle fréquence raisonnable (comprise entre la fréquence basse et la fréquence haute du fichier ATS indiqué), et de conserver la forme (en fréquence) du fichier ATS (donné par l'ATSbufread).

Voir aussi

ATSread, ATSreadnz, ATSinfo, ATSsinnoi, ATSbufread, ATScross, ATSpartialtap, ATSadd, ATSaddnz

Crédits