count

count — Retourne la valeur suivante d'un compteur.

Description

Opcode du greffon counter.

Retourne la valeur suivante d'un compteur en ajoutant l'incrément et en maintenant le compteur dans l'intervalle déclaré.

Syntaxe

kval count icnt

Initialisation

icnt -- l'identifiant d'un objet compteur obtenu d'un appel à cntCreate.

Exécution

Calcule la valeur suivante de l'objet compteur et retourne cette valeur.

kval -- valeur retournée.

Exemples

Voici un exemple de l'opcode count. Il utilise le fichier counter.csd.

Exemple 166. Exemple de l'opcode count.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-odac -Mhw:1,0,0
</CsOptions>

<CsInstruments>
 gicnt cntCreate 1     ; a toggle
 gicntNote cntCreate 1 ; ignore note-off message to turn MIDI notes into toggles


instr 1

kkey sensekey

inote notnum

if (kkey == 97) then
 k1 count gicnt
 if k1==0 then
  event "i", 2, 0, -1
 else
  event "d", 2, 0, -1
 endif
endif

print  inote
if (inote == 60) then
 i2 count_i gicntNote
 print i2
 if i2==0 then
  event_i "i", 3, 0, -1
 else
  event_i "d", 3, 0, -1
 endif
endif
endin

instr 2
asig oscil 10000, 440
out asig
endin

instr 3
asig oscil 5000, 880
out asig
endin

</CsInstruments>


<CsScore>
i1 0 z
e

</CsScore>

</CsoundSynthesizer>


Voir aussi

cntCreate count_i cntCycles cntRead cntReset cntState

Crédits

Par : John ffitch juin 2020

Nouveau dans la version 6.15