fmanal

fmanal — Analyse MA/MF d'un signal en quadrature.

Description

Cet opcode tente d'extraire les signaux MA et MF d'un signal en quadrature (par exemple d'une transformée de Hilbert).

Syntaxe

am, af fmanal are, aim

Exécution

are -- signal réel en entrée (phase cosinus)

aim -- signal imaginaire en entrée (phase sinus)

am -- enveloppe de la modulation d'amplitude.

af -- enveloppe de la modulation de fréquence.

fmanal prend un signal en quadrature (parties réelles et imaginaires) et restitue les signaux de MA et de MF estimés. Le premier est le module de chaque paire en entrée (|re + j*im|) et le second est la dérivée d'arg(re + j*im). Chaque échantillon en sortie est l'amplitude et la fréquence instantanées estimées du signal d'entrée.

Exemple

Voici un exemple de l'opcode fmanal. Il utilise le fichier fmanal.csd.

Exemple 345. Exemple de l'opcode fmanal.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 64
nchnls = 2
0dbfs = 1

instr 1

asig oscili p4, p5
a1,a2 hilbert2 asig,1024,256
am,afm fmanal a1,a2
ktrig metro 2
printf "AM=%.3f FM=%.1f\n",ktrig,k(am),k(afm)
  outs a1, a2

endin


</CsInstruments>
<CsScore>
i1 0 10 0.5 440
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Victor Lazzarini
2017