getcfg

getcfg — Retourne les réglages de Csound.

Description

Retourne différents réglages de configuration dans Svalue sous forme de chaîne de caractères, pendant l'initialisation.

Syntaxe

Svalue getcfg iopt

Initialisation

iopt -- le paramètre à retourner ; peut être un de ceux-ci :

  • 1 : la longueur maximale des variables chaîne, en caractères ; vaut au moins la valeur de l'option -+max_str_len de la ligne de commande - 1.

    [Note] Note
    Dans Csound6 il n'y a pas de longueur maximale pour les chaînes de caractères, ce qui ôte toute signification à la valeur retournée.
  • 2 : le nom du fichier son en entrée (-i), ou une chaîne vide s'il n'y a pas de fichier en entrée

  • 3 : le nom du fichier son en sortie (-o), ou une chaîne vide s'il n'y a pas de fichier en sortie

  • 4 : retourne "1" si une entrée ou une sortie audio en temps réel est utilisée, "0" sinon

  • 5 : retourne "1" si l'exécution est en mode pulsation (option -t de la ligne de commande), "0" sinon

  • 6 : le nom du système d'exploitation hôte

  • 7 : retourne "1" si une fonction de rappel a été installée pour les opcodes chnrecv et chnsend, "0" sinon (ce qui veut dire que ces opcodes ne font rien)

Exemples

Voici un exemple de l'opcoce getcfg. Il utilise le fichier getcfg.csd.

Exemple 420. Exemple de l'opcoce getcfg.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer> 
<CsOptions> 
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
-iadc    ;;;uncomment -iadc if realtime audio input is needed too
</CsOptions> 
<CsInstruments> 

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

S1 getcfg 1	; -+max_str_len 
S2 getcfg 2	; -i 
S3 getcfg 3	; -o 
S4 getcfg 4	; RTaudio 
S5 getcfg 5	; -t 
S6 getcfg 6	; os system host 
S7 getcfg 7	; callback 

prints "------------------------------" 
prints "\nMax string len : " 
prints	S1 
prints "\nInput file name (-i) : " 
prints	S2 
prints "\nOutput file name (-o) : " 
prints	S3 
prints "\nRTaudio (-odac) : " 
prints	S4 
prints "\nBeat mode (-t)? : " 
prints	S5 
prints "\nHost Op. Sys. : " 
prints	S6 
prints "\nCallback ? : " 
prints	S7 
prints "\n" 
prints "------------------------------\n" 

endin 

</CsInstruments> 
<CsScore> 
i 1 0 0 
e 
</CsScore> 
</CsoundSynthesizer> 


Sa sortie comprendra des lignes comme celles-ci :

------------------------------
Max string len : 255
Input file name (-i) : adc
Output file name (-o) : dac
RTaudio (-odac) : 1
Beat mode (-t)? : 0
Host Op. Sys. : Linux
Callback ? : 0
------------------------------

Crédits

Auteur : Istvan Varga
2006

Nouveau dans la version 5.02