gtf

gtf — Applique un filtre gammatone à un signal audio.

Description

Applique un filtre gammatone de différents ordres à un signal audio.

Syntaxe

aout gtf ain, kfreq, idecay[, iorder, iphase]

Initialisation

idecay -- taux de chute

iorder -- (facultatif) Ordre du filtre compris entre 1 et 10 (valeurs entières). Vaut 4 par défaut.

iphase -- (facultatif) Phase en sortie, zéro par défaut.

Exécution

asig -- Signal audio à filtrer.

kfreq -- Fréquence centrale du filtre en Hz.

Le filtre gammatone est habituellement utilisé dans des modèles du système auditif. L'algorithme est basé sur les travaux présentés dans la thèse de doctorat de Martin Cooke (Cooke, 1993) qui utilisent la transformation invariante d'impulsion en bande de base. Voirhttp://staffwww.dcs.shef.ac.uk/people/N.Ma/resources/gammatone/

Exemples

Voici un exemple de l'opcode gtf. Il utilise le fichier gtf.csd.

Exemple 402. Exemple de l'opcode gtf.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o gtf.wav -W ;;; for file output any platform

; By Stefano Cucchi 2020

</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1	 
                                        
kcps  init cpspch(p4) 
asig1 vco2 0.5, kcps ; SOUND

kfreq1 linseg p5, p3, p6 ; frequency filter 1
kfreq2 expseg p6, p3, p5 ; frequency filter 2
idecay = p7 ; keep it very small

afilter1 gtf asig1, kfreq1, idecay ; SOUND - filter 1
afilter2 gtf asig1, kfreq2, idecay ; SOUND - filter 2

aref oscili 0.25, 440 ; AMPLITUDE reference
afilter1 balance afilter1, aref ; compare filtered SOUND with reference
afilter2 balance afilter2, aref ; ; compare filtered SOUND with reference

outs afilter1, afilter2

endin

</CsInstruments>


<CsScore>

i 1 0 5 6.00 200 12000 0.1
i 1 5 5 6.00 200 12000 0.01		


e
</CsScore>
</CsoundSynthesizer>


Crédits

Par : John ffitch 2019