mandol

mandol — Une simulation de mandoline.

Description

Une simulation de mandoline.

Syntaxe

ares mandol kamp, kfreq, kpluck, kdetune, kgain, ksize \
    [, ifn] [, iminfreq]

Initialisation

ifn -- numéro d'une table contenant la forme d'onde du pincement de corde. Le fichier mandpluk.aiff convient pour cela. On peut aussi l'obtenir à ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

iminfreq (facultatif, 0 par défaut) -- Fréquence la plus basse pour une note. Si ce paramètre est omis, il prend la valeur initiale de kfreq.

Exécution

kamp -- Amplitude de la note.

kfreq -- Fréquence de la note.

kpluck -- Position du pincement sur la corde, compris entre 0 et 1. Valeur suggérée : 0,4.

kdetune -- Proportion de désaccord entre les deux cordes. La valeur suggérée va de 0,9 à 1.

kgain -- le gain de la boucle du modèle, compris entre 0,97 et 1.

ksize -- La taille du corps de la mandoline. Compris entre 0 et 2.

Exemples

Voici un exemple de l'opcode mandol. Il utilise les fichiers mandol.csd, et mandpluk.aiff.

Exemple 569. Exemple de l'opcode mandol.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o mandol.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kamp    = p4
ksize   = p5
kdetune = p6
asig mandol kamp, 880, .4, kdetune, 0.99, ksize, 1, 220
     outs asig, asig

endin
</CsInstruments>
<CsScore>
; "mandpluk.aiff" audio file
f 1 0 8192 1 "mandpluk.aiff" 0 0 0

i 1 .5 1  1  2 .99
i 1 +  1 .5  1 .99	;lower volume to compensate
i 1 +  3 .3 .3 .99	;lower volume to compensate

i 1 4  1  1  2 .39	;change detune value
i 1 +  1 .5  1 .39
i 1 +  3 .3 .3 .39
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : John ffitch (d'après Perry Cook)
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound