ms2st

ms2st — Conversion mid-side stéréo.

Description

Cet opcode implémente une conversion mid-side (MS) vers stéréo avec un contrôle de largeur. C'est une fonction pure sans effet de bord.

Syntaxe

aleft, aright ms2st as, am, kwidth

Exécution

aleft -- sortie sur le canal gauche.

aright -- sortie sur le canal droite.

am -- signal mid en entrée.

as -- signal side en entrée.

kwidth -- largeur stéréo (de 0 à 1). A 0, il n'y a pas de signal side en sortie, et à 1 le signal mid est absent. Une valeur de 0.5 restitue une conversion stéréo vers MS exacte (st2ms).

Exemples

Voici un exemple de l'opcode ms2st. Il utilise les fichiers ms2st.csd, MSjungle_interleaved.wav, MSjungleMid.wav et MSjungleSide.wav.

Exemple 628. Exemple de l'opcode ms2st.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o ms2st.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

; by  Menno Knevel - 2021
; sample = ambient sound of waterfall + animals (monkey, birds)

instr 1 ; MS sample is interleaved

am, as    diskin2    "MSjungle_interleaved.wav", 1, 0, 1 ; interleaved stereo, MS encoded
kwidth = p4                                              ; left = M, right = S
al, ar ms2st  am, as, kwidth
outs al, ar
endin

instr 2 ; 2 separate samples 

am    diskin2    "MSjungleMid.wav", 1        ; M sound as a separate mono sound
as    diskin2    "MSjungleSide.wav", 1       ; S sound as a separate mono sound
kwidth = p4     
al, ar ms2st  am, as, kwidth
outs al, ar

endin
</CsInstruments>
<CsScore>

i1 0 6.7 0          ; M only
i1 + 6.7 .3         ; M and a bit of S
i1 + 6.7 .5         ; M + S equal volume
i1 + 6.7 1          ; S only 

i2 28 6.7 0         ; M only
i2 +  6.7 .3        ; M and a bit of S
i2 +  6.7 .5        ; M + S equal volume
i2 +  6.7 1         ; S only
e
</CsScore>
</CsoundSynthesizer>


un fichier MS à encodage entrelacé : MSjungle_interleaved.wav utilisé dans instr 1

un fichier MS à encodage entrelacé : MSjungle_interleaved.wav utilisé dans instr 1

deux fichiers séparés MSjungleMid.wav et MSjungleSide.wav utiisés dans instr 2

deux fichiers séparés MSjungleMid.wav et MSjungleSide.wav utiisés dans instr 2

Voir aussi

st2ms

Crédits

Auteur : Victor Lazzarini
Avril 2021