ntof

ntof
Précédent	Opcodes et opérateurs de l'orchestre	Suivant

Description

Opcode du greffon emugens.

Convertit un nom de note en fréquence (Hz). Permet d'inclure dans le nom de la note des microtons ou une déviation en cents.

Syntaxe

kfreq ntof Snote

ifreq ntof Snote

Exécution

Snote -- Nom de note

kfreq -- Fréquence

	Note
	La fréquence retournée dépend de la valeur de la variable globale A4.

	Note
	4C est le do médiant du piano.

Exemples

Voici un exemple de l'opcode ntof. Il utilise le fichier ntof.csd.

Exemple 666. Exemple de l'opcode ntof.

<CsoundSynthesizer>
<CsOptions>
--nosound
</CsOptions>
<CsInstruments>

/*

Example for ntof: notename to frequency 

A notename is a string of the form

<octave><pitchclass>[cents]

Example notenames are:

"4A"     -> A in the 4th octave
"5C+31"  -> C5, 31 cents higher
"4Db-13" -> D flat, 4th octave, 13 cents lower
"7F#+"   -> F# quarter tone higher 
"5G-"    -> G5 a quarter tone lower

NB: the frequency returned by ntof depends on the value of A4

*/

A4 = 442

instr 1
    ifreq ntof "4A"
    print ifreq

    koctave = 1
    while (koctave <= 8) do
        Snote sprintfk "%dC", koctave
        kfreq ntof Snote
        printf "notename: %s  freq: %.2f \n", koctave, Snote, kfreq
        koctave += 1
    od

    turnoff
endin

</CsInstruments>
<CsScore>

i 1 0 1

</CsScore>
</CsoundSynthesizer>

Voir aussi

mtof, ftom, mton mton

Crédits

Par : Eduardo Moguillansky 2019

Nouveau dans la 6.13

Précédent	Niveau supérieur	Suivant
nstance	Sommaire	ntom