part2txt

part2txt — Ecrit un fichier texte contenant des données de pistes de partiels

Description

L'opcode part2txt prend en entrée un fsig PVS_TRACKS et écrit les données comme une suite de listes de suivi de partiels, une pour chaque point temporel, dans un fichier texte organisé par lignes. Chaque suivi de partiel est placé dans une ligne séparée contenant l'amplitude, la fréquence, la phase et l'ID du suivi. Une ligne de séparation contenant quatre valeurs -1.0 est utilisée pour définir la fin de la liste de suivi pour un point temporel donné.

Syntaxe

part2txt SFile, ftrks

Initialisation

SFile -- nom du fichier de sortie.

Exécution

ftrks -- flot pv en sortie au format TRACKS.

Exemple

Voici un exemple de l'opcode part2txt. Il utilise le fichier part2txt.csd.

Exemple 697. Exemple de l'opcode part2txt.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-n
</CsOptions>
<CsInstruments>

instr 1
isiz = 2048
ihsiz = isiz/4
S1 = "flutec3.wav"
p3 = filelen(S1)
ain diskin2 S1,1
ffr,fphs  pvsifd   ain, isiz, ihsiz, 1
ftrk      partials ffr, fphs, 0.01, 1, 1, 500
part2txt "partialsh.txt",ftrk
endin

</CsInstruments>
<CsScore>
i1 0 1
</CsScore>
</CsoundSynthesizer>


L'exemple ci-dessus montre la détection et le suivi de partiel d'un signal analysé par ifd et sa resynthèse additive avec interpolation cubique de phase et transposition de hauteur.

Crédits

Auteur : Victor Lazzarini
Juin 2015