portk

portk — Applique un portamento à un signal de contrôle en escalier.

Description

Applique un portamento à un signal de contrôle en escalier.

Syntaxe

kres portk ksig, khtim [, isig]

Initialisation

isig (facultatif, par défaut 0) -- valeur initiale (c-à-d. précédente) pour la rétroaction interne. La valeur par défaut est 0.

Exécution

kres -- le signal de sortie au taux de contrôle.

ksig -- le signal d'entrée au taux de contrôle.

khtim -- durée à mi-parcours de la fonction, en secondes.

portk est semblable à port à part le fait que la durée à mi-parcours peut-être variée au taux de contrôle.

Exemples

Voici un exemple de l'opcode portk. Il utilise le fichier portk.csd.

Exemple 761. Exemple de l'opcode portk.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o portk.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; by Stefano Cucchi 2020

sr = 44100 
ksmps = 32 
0dbfs  = 1 
nchnls = 2

instr 1

kFreq randomh 400, 1300, 4, 2, 550 ; random frequency to oscillators.

khtim linseg 0.001, p3*0.3, 0.001, p3*0.7, 0.125 ; portamento-function: start with NO portamento - then portamento.
kPort portk kFreq, khtim ; pitch with portamento.

asigL oscili 0.4, kFreq, 1 ; channel left - NO portamento.
asigR oscili 0.4, kPort, 2 ; channel right - PORTAMENTO.

outch 1, asigL   ; channel left
outch 2, asigR   ; channel right

endin

</CsInstruments>
<CsScore>

f 1 0 4096 10 1 0 1 0 1 0 1 0 1
f 2 0 4096 10 1 1 0 1 0 1 0 1 0 1

i 1 0 10
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

areson, aresonk, atone, atonek, port, reson, resonk, tone, tonek

Crédits

Auteur : Robin Whittle
Australie
Mai 1997