Description

Ces unités affichent des valeurs d'initialisation de l'orchestre.

Syntaxe

print iarg [, iarg1] [, iarg2] [...]

Initialisation

iarg, iarg2, ... -- arguments de taux-i.

Exécution

print -- affiche la valeur courante des arguments (ou des expressions) de taux-i iarg à chaque passe d'initialisation dans l'instrument.

	Note
	L'opcode print tronque des positions décimales et peut ainsi ne pas montrer la valeur complète. La précision de Csound varie selon la version float (32 bit) ou double (64 bit), car la plupart des calculs internes utilisent un de ces formats. Si l'on désire une sortie console avec plus de résolution, on peut essayer printf.

Exemples

Voici un exemple de l'opcode print. Il utilise le fichier print.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o print.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

irand = rnd(3)			;generate a random number from 0 to 3
print irand			;print it
asig  poscil .7, 440*irand, 1
      outs asig, asig

endin
</CsInstruments>
<CsScore>
f1 0 16384 10 1	;sine wave

i 1 0 1
i 1 2 1
i 1 4 1
e
</CsScore>
</CsoundSynthesizer>

Sa sortie contiendra des lignes comme celles-ci :

+instr 1:  irand = 2.930
+instr 1:  irand = 0.420
+instr 1:  irand = 2.316

Voir aussi

dispfft, display, printk, printk2, printks , printf and prints