Description

Suspend une exécution tandis que se déroule une phase spéciale d'initialisation.

Chaque fois que cette instruction est rencontrée durant une phase d'exécution, celle-ci est temporairement suspendue tandis qu'une phase spéciale d'initialisation, commençant à label et allant jusqu'à rireturn ou endin, a lieu. L'exécution reprend ensuite à partir de l'endroit où elle fut interrompue.

Syntaxe

reinit label

Exemples

Les instructions suivantes génèrent un signal de contrôle exponentiel dont les valeurs vont de 440 à 880 exactement dix fois pendant la durée p3. Elles utilisent le fichier reinit.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac      ;;;RT audio out
; For Non-realtime ouput leave only the line below:
; -o reinit.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

reset:
        timout 0, p3/p4, contin         
        reinit reset

contin:
        kLine expon 440, p3/p4, 880
        aSig poscil 1, kLine
        outs aSig, aSig
        rireturn

endin

</CsInstruments>
<CsScore>

i1 0 10 10
i1 + 10 50      
e
</CsScore>
</CsoundSynthesizer>

Voir aussi

rigoto, rireturn