sprintf

sprintf — Sortie formattée à la printf dans une variable chaîne de caractères.

Description

sprintf écrit une sortie formatée à la printf dans une variable chaîne de caractères, comme le fait la fonction C sprintf(). sprintf ne s'exécute que pendant l'initialisation.

Syntaxe

Sdst sprintf Sfmt, xarg1[, xarg2[, ... ]]

Initialisation

Sfmt -- chaîne de formatage comme dans printf() et d'autres fonctions C similaires, sauf que les modificateurs de longueur (l, ll, h, etc.) ne sont pas supportés. Les spécificateurs de conversion suivants sont permis :

  • d, i, o, u, x, X, e, E, f, F, g, G, c, s

xarg1, xarg2, ... -- arguments d'entrée (max. 30) à formater, doivent être de taux-i pour tous les spécificateurs de conversion sauf pour %s, qui nécessite un argument chaîne de caractères. Les formats d'entiers comme %d arrondissent les valeurs d'entrée à l'entier le plus proche.

Exécution

Sdst -- variable chaîne de caractères en sortie

Exemples

Voici un exemple de l'opcode sprintf. Il utilise le fichier sprintf.csd.

Exemple 997. Exemple de l'opcode sprintf.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sprintf.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

;the file "impuls20.aiff" can be found in /manual/examples
instr 1

ifn = 20
Sname sprintf "impuls%02d.aiff", ifn
Smsg  sprintf "The file name is: '%s'", Sname
      puts    Smsg, 1
asig  soundin Sname
      outs asig, asig

endin
</CsInstruments>
<CsScore>

i 1 0 1
e
</CsScore>
</CsoundSynthesizer>


Sa sortie contiendra des lignes comme celles-ci :

The file name is: 'impuls20.aiff'
soundin: opened 'impuls20.aiff'

Voir aussi

sprintfk

Crédits

Auteur : Istvan Varga
2005