timeinsts

timeinsts — Lit le temps absolu en secondes.

Description

Lit le temps absolu en secondes, depuis le démarrage d'une instance d'un instrument.

Syntaxe

kres timeinsts

Exécution

Le temps en secondes est donné par timeinsts. Il retournera 0.5 après une demi-seconde.

timeinsts produit une variable de taux-k en sortie. Il n'y a pas de paramètres d'entrée.

timeinsts est semblable à times sauf qu'il retourne le temps écoulé depuis le démarrage de cette instance de l'instrument.

Exemples

Voici un exemple de l'opcode timeinsts. Il utilise le fichier timeinsts.csd.

Exemple 1099. Exemple de l'opcode timeinsts.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o timeinsts.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

giSine ftgen 0, 0, 2^10, 10, 1

instr 1

kvib init 1
ktim timeinsts				;read time 

if ktim > 2 then			;do something after 2 seconds
   kvib oscili 2, 3, giSine		;make a vibrato
endif

asig poscil .5, 600+kvib, giSine	;add vibrato
     outs asig, asig

endin 
</CsInstruments>
<CsScore>

i 1 0 5
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

timeinstk, timek, times

Crédits

Auteur : Robin Whittle
Australie
Mai 1997