waveset

waveset — Un variateur de durée simple par répétition de périodes.

Description

Un variateur de durée simple par répétition de périodes.

Syntaxe

ares waveset ain, krep [, ilen]

Initialisation

ilen (facultatif, 0 par défaut) -- la longueur (en échantillons) du signal audio. Si ilen vaut 0, la moitié de la longueur de la note donnée (p3) est prise.

Exécution

ain -- le signal audio en entrée.

krep -- le nombre de fois que la période est répétée.

L'entrée est lue et chaque période complète (deux passages par zéro) est répétée krep fois.

Il y a un tampon interne car la sortie est évidemment plus lente que l'entrée. Il faut faire attention si le tampon est trop court, car il peut y avoir des effets étranges.

Exemples

Voici un exemple de l'opcode waveset. Il utilise le fichier waveset.csd.

Exemple 1209. Exemple de l'opcode waveset.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o waveset.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs   =1

instr 1

krep init p4
asig soundin "flute.aiff"
aout waveset asig, krep
     outs aout, aout
  
endin
</CsInstruments>
<CsScore>

i 1 0 3 1	;no repetitions
i 1 + 10 3	;stretching 3 times
i 1 + 14 6	;6 times

e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : John ffitch
Février 2001

Nouveau dans la version 4.11