wgbow

wgbow — Simule un son de corde frottée.

Description

La sortie audio simule un son de corde frottée, réalisé au moyen d'un modèle physique développé par Perry Cook, mais recodé pour Csound.

Syntaxe

ares wgbow kamp, kfreq, kpres, krat, kvibf, kvamp \
    [, ifn] [, iminfreq]

Initialisation

ifn -- table facultative contenant la forme du vibrato, par défaut une table de sinus.

iminfreq (facultatif) -- fréquence la plus grave à laquelle l'instrument sera joué. Si elle est omise, elle prend la valeur initiale de kfreq. Si iminfreq est négative, l'initialisation est ignorée.

Exécution

Une note est jouée sur un instrument de type corde, avec les arguments ci-dessous.

kamp -- amplitude de la note.

kfreq -- fréquence de la note jouée.

kpres -- un paramètre contrôlant la pression de l'archet sur la corde. Les valeurs doivent se situer autour de 3. L'intervalle utile va approximativement de 1 à 5.

krat -- la position de l'archet le long de la corde. Le jeu habituel se fait environ à 0.127236. L'intervalle recommandé va de 0.025 à 0.23.

kvibf -- fréquence du vibrato en Hz. L'intervalle recommandé va de 0 à 12.

kvamp -- l'amplitude du vibrato.

Exemples

Voici un exemple de l'opcode wgbow. Il utilise le fichier wgbow.csd.

Exemple 1212. Exemple de l'opcode wgbow.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o wgbow.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kpres = p4							;pressure value
krat = p5							;position along string
kvibf = 6.12723

kvib  linseg 0, 0.5, 0, 1, 1, p3-0.5, 1				; amplitude envelope for the vibrato.		
kvamp = kvib * 0.01
asig  wgbow .7, 55, kpres, krat, kvibf, kvamp, 1
      outs asig, asig

endin
</CsInstruments>
<CsScore>
f 1 0 2048 10 1	;sine wave

i 1 0 3 3 0.127236
i 1 + 3 5 0.127236
i 1 + 3 5 0.23

e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : John ffitch (d'après Perry Cook)
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound

ifn est devenu facultatif dans la version 6.06