zdf_1pole_mode

zdf_1pole_mode — Implémentation d'un filtre à 1 pôle avec rétroaction sans retard et sortie multimodale.

Description

Implémentation d'un filtre à 1 pôle avec rétroaction sans retard (6 dB/oct). Propose une sortie passe-bas et passe-haut.

Syntaxe

alp, ahp zdf_1pole_mode ain, xcf [, istor]

Initialisation

istor -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

Exécution

alp -- signal de sortie passe-bas.

ahp -- signal de sortie passe-haut.

asig -- signal d'entrée.

xcf -- fréquence de coupure du filtre (taux-i-, k ou a).

Exemples

Voici un exemple de l'opcode zdf_1pole_mode. Il utilise le fichier zdf_1pole_mode.csd.

Exemple 1244. Example of the zdf_1pole_mode opcode.

<CsoundSynthesizer>
<CsOptions>
-o dac
</CsOptions>
<CsInstruments>

sr	=	48000
ksmps	=	1
nchnls	=	2
0dbfs	=	1

instr 1	
  asig = random:a(-1.0, 1.0) 
  alp, ahp zdf_1pole_mode asig, line(220, p3, 10000)
  asig = (p4 == 0) ? alp : ahp
  outc(asig, asig)
endin

instr 2	
  asig = vco2(0.5, 220)
  alp, ahp zdf_1pole_mode asig, line(220, p3, 10000)
  asig = (p4 == 0) ? alp : ahp
  outc(asig, asig)
endin

</CsInstruments>
<CsScore>
i1 0 4 0
i1 5 4 1
i2 10 4 0
i2 15 4 1
</CsScore>
</CsoundSynthesizer>


Références

Ce filtre est basé sur les travaux de Will Pirkle qui emploie le travail de Vadim Zavalishin pour créer des implémentation de filtres analogiques à transformation préservant la topologie (TPT), avec des transformées bilinéaires.

  1. Pirkle, Will. Designing Software Synthesizer Plug-ins in C++: For RackAFX, VST3, and Audio Units. CRC Press, 2014.

  2. Pirkle, Will. AN-4: Virtual Analog (VA) Filter Implementation. 2013.

  3. Zavalishin, Vadim. "The Art of VA filter design." Native Instruments, 2012.

Crédits

Auteur : Steven Yi
Avril 2017

Nouveau dans Csound 6.09.0