cpsmidi

cpsmidi — Get the note number of the current MIDI event, expressed in cycles-per-second.

Description

Get the note number of the current MIDI event, expressed in cycles-per-second.

Syntax

icps cpsmidi

Performance

Get the note number of the current MIDI event, expressed in cycles-per-second units, for local processing.

[Note] cpsmidi vs. cpsmidinn

The cpsmidi opcode only produces meaningful results in a Midi-activated note (either real-time or from a Midi score with the -F flag). With cpsmidi, the Midi note number value is taken from the Midi event that is internally associated with the instrument instance. On the other hand, the cpsmidinn opcode may be used in any Csound instrument instance whether it is activated from a Midi event, score event, line event, or from another instrument. The input value for cpsmidinn might for example come from a p-field in a textual score or it may have been retrieved from the real-time Midi event that activated the current note using the notnum opcode.

Examples

Here is an example of the cpsmidi opcode. It uses the file cpsmidi.csd.

Example 175. Example of the cpsmidi opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     -M0  ;;;RT audio I/O with MIDI in
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o cpsmidi.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1
icps cpsmidi
asig	oscil 0.6, icps, 1
	print icps
	outs  asig, asig

endin

</CsInstruments>
<CsScore>
f0 20
;sine wave.
f 1 0 16384 10 1

e
</CsScore>
</CsoundSynthesizer>


See Also

aftouch, ampmidi, cpsmidib, cpstmid, midictrl, notnum, octmidi, octmidib, pchbend, pchmidi, pchmidib, veloc, cpsmidinn, octmidinn, pchmidinn

Credits

Author: Barry L. Vercoe - Mike Berry
MIT - Mills
May 1997