Description

Read sampled sound (mono or stereo) from a table, with optional sustain and release looping. A version that outputs the exact table position (phase) corresponding to the output sample is provided as an alternative opcode.

Syntax

ar1 [,ar2] loscil xamp, kcps, ifn [, ibas] [, imod1] [, ibeg1] [, iend1] \
    [, imod2] [, ibeg2] [, iend2]

aph, ar1 [,ar2] loscilphs xamp, kcps, ifn [, ibas] [, imod1] [, ibeg1] [, iend1] \
      [, imod2] [, ibeg2] [, iend2]

Initialization

ifn -- function table number, typically denoting an sampled sound segment with prescribed looping points loaded using GEN01. The source file may be mono or stereo.

ibas (optional) -- base frequency in Hz of the recorded sound. This optionally overrides the frequency given in the audio file, but is required if the file did not contain one. The default value is 261.626 Hz, i.e. middle C. (New in Csound 4.03). If this value is not known or not present, use 1 here and in kcps.

imod1, imod2 (optional, default=-1) -- play modes for the sustain and release loops. A value of 1 denotes normal looping, 2 denotes forward & backward looping, 0 denotes no looping. The default value (-1) will defer to the mode and the looping points given in the source file. Make sure you select an appropriate mode if the file does not contain this information.

ibeg1, iend1, ibeg2, iend2 (optional, dependent on mod1, mod2) -- begin and end points of the sustain and release loops. These are measured in sample frames from the beginning of the file, so will look the same whether the sound segment is monaural or stereo. If no loop points are specified, and a looping mode (imod1, imod2) is given, the file will be looped for the whole length.

Performance

aph -- the normalised table position corresponding to the output sample (loscilphs only).

ar1, ar2 -- the output at audio-rate. There is just ar1 for mono output. However, there is both ar1 and ar2 for stereo output.

xamp -- the amplitude of the output signal.

kcps -- the frequency of the output signal in cycles per second.

loscil samples the ftable audio at a rate determined by kcps, then multiplies the result by xamp. The sampling increment for kcps is dependent on the table's base-note frequency ibas, and is automatically adjusted if the orchestra sr value differs from that at which the source was recorded. In this unit, ftable is always sampled with interpolation.

If sampling reaches the sustain loop endpoint and looping is in effect, the point of sampling will be modified and loscil will continue reading from within that loop segment. Once the instrument has received a turnoff signal (from the score or from a MIDI noteoff event), the next sustain endpoint encountered will be ignored and sampling will continue towards the release loop end-point, or towards the last sample (henceforth to zeros).

loscil is the basic unit for building a sampling synthesizer. Given a sufficient set of recorded piano tones, for example, this unit can resample them to simulate the missing tones. Locating the sound source nearest a desired pitch can be done via table lookup. Once a sampling instrument has begun, its turnoff point may be unpredictable and require an external release envelope; this is often done by gating the sampled audio with linenr, which will extend the duration of a turned-off instrument by a specific period while it implements a decay.

If you want to loop the whole file, specify a looping mode in imod1 and do not enter any values for ibeg and iend.

Note to Windows users

Windows users typically use back-slashes, “\”, when specifying the paths of their files. As an example, a Windows user might use the path “c:\music\samples\loop001.wav”. This is problematic because back-slashes are normally used to specify special characters. To correctly specify this path in Csound, one may alternately: Use forward slashes: c:/music/samples/loop001.wav Use back-slash special characters, “\\”: c:\\music\\samples\\loop001.wav

	Note
	This is mono loscil: a1 loscil 10000, 1, 1, 1 ,1 ...and this is stereo loscil: a1, a2 loscil 10000, 1, 1, 1 ,1

Examples

Here is an example of the loscil opcode. It uses the files loscil.csd, drumsMlp.wav and drumsSlp.wav.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o loscil.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; by Menno Knevel 20222

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1     ; loscil makes use of embedded loop points in wav

ichnls = ftchnls(p4)
prints  "\nnumber of channels = %d\n\n", ichnls

if (ichnls == 1) then                   ; sample is played 2 x faster
   asigL loscil .8, 1.5, p4, 1          ; sample loops between 1 and end loop point at 2 secs. in sample
   asigR = 	asigL
elseif (ichnls == 2) then               ; sample is played at half speed
   asigL, asigR loscil .8, .5, p4, 1    ; sample loops between 2 and end loop point at 3 secs. in sample
else                                    ; safety precaution if not mono or stereo
   asigL = 0
   asigR = 0
endif
        outs asigL, asigR

endin
</CsInstruments>
<CsScore>
f 1 0 0 1 "drumsMlp.wav" 0 0 0
f 2 0 0 1 "drumsSlp.wav" 0 0 0

i 1 0 7 1   ;mono file
i 1 7 12 2  ;stereo file
e
</CsScore>
</CsoundSynthesizer>

See Also

loscil3 and GEN01

Credits

Note about the mono/stereo difference was contributed by Rasmus Ekman.