trighold

trighold — Timed trigger, holds a value for a given time

Description

Plugin opcode in scugens.

Timed trigger. Port of Supercollider's Trig ugen. When a nonpositive to positive transition occurs at the input, trighold outputs the level of the triggering input for the specified duration, otherwise it outputs zero.

Syntax

aout trighold ain, kdur
kout trighold kin, kdur

Initialization

initialvalue If given, sets the internal state. Default=0

Performance

ain -- Trigger. Trigger can be any signal. A trigger happens when the signal changes from non-positive to positive.

kdur -- Duration of the trigger in seconds.

Examples

Here is an example of the trighold opcode. It uses the file trighold.csd.

Example 909. Example of the trighold opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 128
nchnls = 2
0dbfs = 1.0

instr 1
  km = metro(1)
  kt timeinsts
  ktrig = trighold(km, 0.5)
  printks "t=%f  km=%f    ktrig=%f\n", 0.01, kt, km, ktrig
endin

instr 2
  am = upsamp(metro(1))
  aenv = trighold(am, 0.5)
  asig pinker
  outch 1, asig*aenv
  outch 2, asig
endin

</CsInstruments>
<CsScore>
i 1 0 10
i 2 0 10

</CsScore>
</CsoundSynthesizer>


See Also

lag, metro, mpulse trigger

Credits

By: Eduardo Moguillansky 2017