zacl

zacl — Clears one or more variables in the za space.

Description

Clears one or more variables in the za space.

Syntax

zacl kfirst [, klast]

Performance

kfirst -- first za location in the range to clear.

klast -- last za location in the range to clear. If not given, only kfirst location is cleared

zacl clears one or more variables in the za space. This is useful for those variables which are used as accumulators for mixing a-rate signals at each cycle, but which must be cleared before the next set of calculations.

Examples

Here is an example of the zacl opcode. It uses the file zacl.csd.

Example 1229. Example of the zacl opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in    No messages
-odac         -iadc       -d     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o zacl.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; Initialize the global variables.
sr = 44100
ksmps = 32
nchnls = 1
0dbfs = 1

; Initialize the ZAK space.
; Create 1 a-rate variable and 1 k-rate variable.
zakinit 1, 1

; Instrument #1 -- a simple waveform.
instr 1
  ; Generate a simple sine waveform.
  asin oscili 0.2, 440

  ; Declick
  asin *= linsegr(0, 0.05, 1, 0.05, 0)

  ; Send the sine waveform to za variable #1.
  zaw asin, 1
endin

; Instrument #2 -- generates audio output.
instr 2
  ; Send za location #1 to channel 1
  a1 zar 1
  out a1

  ; Clear the za variables, get them ready for 
  ; another pass.
  zacl 0, 1
endin


</CsInstruments>
<CsScore>

; Play Instrument #1 for one second.
i 1 0 1
; Play Instrument #2 until end of performance
i 2 0 -1
e 1.5

</CsScore>
</CsoundSynthesizer>


See Also

zamod, zar, zaw, zawm, ziw, ziwm

Credits

Author: Robin Whittle
Australia
May 1997

New in version 3.45

Example written by Kevin Conder.