Skip to content

ATSinterpread

Allows a user to determine the frequency envelope of any ATSbufread.

Syntax

kamp ATSinterpread kfreq

Performance

kfreq - a frequency value (given in Hertz) used by ATSinterpread as in index into the table produced by an ATSbufread.

ATSinterpread takes a frequency value (kfreq in Hz). This frequency is used to index the data of an ATSbufread. The return value is an amplitude gained from the ATSbufread after interpolation. ATSinterpread allows a user to determine the frequency envelope of any ATSbufread. This data could be useful for an number of reasons, one might be performing cross synthesis of data from an ATS file and non ATS data.

Examples

Here is an example of the ATSinterpread opcode. It uses the file ATSinterpread.csd.

Example of the ATSinterpread opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc for RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o ATSinterpread.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

; by Menno Knevel - 2021

ires system_i 1,{{ atsa fox.wav fox.ats }} ; ATSA wants a mono file!

instr 1 

ktime   line    0, p3, 2.65
        ATSbufread ktime, 1, "fox.ats", p4
kamp    ATSinterpread   p5  ; get envelope from partial
aosc    poscil3 kamp, p5
        outs    aosc * 8, aosc * 8

endin

</CsInstruments>
<CsScore>
;              partial     index         
s
i 1 0 2.65      12          1000
i 1 3 2.65      12          150
i 1 6 2.65      12          10000
s
i 1 0 2.65      72          1000
i 1 3 2.65      72          150
i 1 6 2.65      72          10000
e
</CsScore>
</CsoundSynthesizer>

This example shows how to use ATSinterpread. Here a frequency is given by the score (p5) and this frequency is given to an ATSinterpread (with a corresponding ATSbufread). The ATSinterpread uses this frequency to output a corresponding amplitude value, based on the atsfile given by the ATSbufread (beats.ats in this case). We then use that amplitude to scale a sine-wave that is synthesized with the same frequency (p5). You could extend this to include multiple sine-waves. This way you could synthesize any reasonable frequency (within the low and high frequencies of the indicated ATS file), and maintain the shape (in frequency) of the indicated atsfile (given by the ATSbufread).

See also

ATS Spectral Processing

Credits

Author: Alex Norman
Seattle,Washington
2004