Skip to content

+

Addition operator.

Arithmetic operators perform operations of change-sign (negate), do-no-change-sign, logical AND logical OR, add, subtract, multiply and divide. Note that a value or an expression may fall between two of these operators, either of which could take it as its left or right argument, as in

\[ a + b * c. \]

In such cases three rules apply:

  1. \(*\) and \(/\) bind to their neighbors more strongly than \(+\) and \(-\). Thus the above expression is taken as:
    \(a + (b * c)\) with \(*\) taking \(b\) and \(c\) and then \(+\) taking \(a\) and \(b * c\).

  2. \(+\) and \(-\) bind more strongly than &&, which in turn is stronger than ||:
    \(a \;\&\&\; b - c \;||\; d\) is taken as \((a \;\&\&\; (b - c))\;||\; d\)

  3. When both operators bind equally strongly, the operations are done left to right:
    \(a - b - c\) is taken as \((a - b) - c\)

Parentheses may be used as above to force particular groupings.

Syntax

+a  (no rate restriction)
a + b  (no rate restriction)

where the arguments \(a\) and \(b\) may be further expressions.

Arguments

The arguments of \(+\) can be scalar values or k-rate one dimensional arrays (vectors), or any combination. If one of the arguments is an array, so is the value.

Examples

Here is an example of the + operator. It uses the file adds-modern.csd.

Example of the + operator.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
-d        ;;;no display
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o adds.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1
  ; add unipolar square to oscil
  amp:k = p4
  cps:k = 1
  type:i = 3

  klfo = lfo(amp, cps, type)
  printk2(klfo)
  sig:a = poscil(0.7, 440+klfo, 1)
  outs(sig, sig)
endin

</CsInstruments>
<CsScore>
;sine wave.
f 1 0 32768 10 1

i 1 0 2 1       ;adds 1 Hz to frequency
i 1 + 2 10      ;adds 10 Hz to frequency
i 1 + 2 220     ;adds 220 Hz to frequency

e

</CsScore>
</CsoundSynthesizer>

Here is an example of the + operator. It uses the file adds.csd.

Example of the + operator.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o adds.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1
; add unipolar square to oscil
kamp = p4
kcps = 1
itype = 3

klfo    lfo kamp, kcps, itype
printk2 klfo
asig    oscil 0.7, 440+klfo, 1
        outs asig, asig

endin


</CsInstruments>
<CsScore>
;sine wave.
f 1 0 32768 10 1

i 1 0 2 1       ;adds 1 Hz to frequency
i 1 + 2 10      ;adds 10 Hz to frequency
i 1 + 2 220     ;adds 220 Hz to frequency

e

</CsScore>
</CsoundSynthesizer>

See also

Arithmetic and Logic Operations

Credits

Arithmetic on vectors is new in version 6.00