Skip to content

adsynt

Performs additive synthesis with an arbitrary number of partials, not necessarily harmonic.

Syntax

ares = adsynt(kamp, kcps, iwfn, ifreqfn, iampfn, icnt [, iphs])

ares adsynt kamp, kcps, iwfn, ifreqfn, iampfn, icnt [, iphs]

Initialization

iwfn -- table containing a waveform, usually a sine. Table values are not interpolated for performance reasons, so larger tables provide better quality.

ifreqfn -- table containing frequency values for each partial. ifreqfn may contain beginning frequency values for each partial, but is usually used for generating parameters at runtime with tablew. Frequencies must be relative to kcps. Size must be at least icnt.

iampfn -- table containing amplitude values for each partial. iampfn may contain beginning amplitude values for each partial, but is usually used for generating parameters at runtime with tablew. Amplitudes must be relative to kamp. Size must be at least icnt.

icnt -- number of partials to be generated

iphs -- initial phase of each oscillator, if iphs = -1, initialization is skipped. If iphs > 1, all phases will be initialized with a random value.

Performance

kamp -- amplitude of note

kcps -- base frequency of note. Partial frequencies will be relative to kcps.

Frequency and amplitude of each partial is given in the two tables provided. The purpose of this opcode is to have an instrument generate synthesis parameters at k-rate and write them to global parameter tables with the tablew opcode.

Examples

Here is an example of the adsynt opcode. These two instruments perform additive synthesis. The output of each sounds like a Tibetan bowl. The first one is static, as parameters are only generated at init-time. In the second one, parameters are continuously changed.

Uses the file adsynt-modern.csd.

Example of the adsynt opcode.
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
-d        ;;;no display
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o adsynt.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs =  1

; Generate a sinewave table.
wave@global:i = ftgen(1, 0, 1024, 10, 1)
; Generate two empty tables for adsynt.
frqs@global:i = ftgen(2, 0, 32, 7, 0, 32, 0)
; A table for freqency and amp parameters.
amps@global:i = ftgen(3, 0, 32, 7, 0, 32, 0)

; Generates parameters at init time
instr 1
  ; Generate 10 voices.
  cnt:i = 10 
  ; Init loop index.
  index = 0 

  ; Loop only executed at init time.
  while index < cnt do 
    ; Define non-harmonic partials.
    freq:i = pow(index + 1, 1.5)
    ; Define amplitudes.
    amp:i = 1 / (index+1)
    ; Write to tables.
    tableiw(freq, index, frqs)
    ; Used by adsynt.
    tableiw(amp, index, amps)
    index += 1
  od

  sig:a = adsynt(0.3, 150, wave, frqs, amps, cnt)
  outs(sig, sig)
endin

; Generates parameters every k-cycle.
instr 2 
  ; Generate 10 voices.
  cnt:i = 10 
  ; Reset loop index.
  index:k = 0

  ; Loop executed every k-cycle.
  while index < cnt do 
    ; Generate lfo for frequencies.
    speed:k = pow(index + 1, 1.6)
    ; Individual phase for each voice.
    phas:k = phasorbnk(speed * 0.7, index, cnt)
    lfo_sig:k = table(phas, wave, 1)
    ; Arbitrary parameter twiddling...
    depth:k = pow(1.4, index)
    freq:k = pow(index + 1, 1.5)
    freq += lfo_sig*0.006*depth

    ; Write freqs to table for adsynt.
    tablew(freq, index, frqs) 

    ; Generate lfo for amplitudes.
    speed = pow(index + 1, 0.8)
    ; Individual phase for each voice.
    phas = phasorbnk(speed*0.13, index, cnt, 2)
    lfo_sig = table(phas, wave, 1)
    ; Arbitrary parameter twiddling...
    amp:k = pow(1 / (index + 1), 0.4)
    amp *= (0.3 + 0.35*(lfo_sig+1))

    ; Write amps to table for adsynt.
    tablew(amp, index, amps)

    index += 1
  od

  sig:a = adsynt(0.25, 150, wave, frqs, amps, cnt)
  outs(sig, sig)
endin


</CsInstruments>
<CsScore>

; Play Instrument #1 for 2.5 seconds.
i 1 0 2.5
; Play Instrument #2 for 2.5 seconds.
i 2 3 2.5
e

</CsScore>
</CsoundSynthesizer>

Uses the file adsynt.csd.

Example of the adsynt opcode.
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o adsynt.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1
; Generate a sinewave table.
giwave ftgen 1, 0, 1024, 10, 1
; Generate two empty tables for adsynt.
gifrqs ftgen 2, 0, 32, 7, 0, 32, 0
; A table for freqency and amp parameters.
giamps ftgen 3, 0, 32, 7, 0, 32, 0

; Generates parameters at init time
instr 1
  ; Generate 10 voices.
  icnt = 10 
  ; Init loop index.
  index = 0 

; Loop only executed at init time.
loop: 
  ; Define non-harmonic partials.
  ifreq pow index + 1, 1.5 
  ; Define amplitudes.
  iamp = 1 / (index+1) 
  ; Write to tables.
  tableiw ifreq, index, gifrqs 
  ; Used by adsynt.
  tableiw iamp, index, giamps 

  index = index + 1
  ; Do loop/
  if (index < icnt) igoto loop 

  asig adsynt 0.3, 150, giwave, gifrqs, giamps, icnt
  outs asig, asig
endin

; Generates parameters every k-cycle.
instr 2 
  ; Generate 10 voices.
  icnt = 10 
  ; Reset loop index.
  kindex = 0

; Loop executed every k-cycle.
loop:
  ; Generate lfo for frequencies.
  kspeed  pow kindex + 1, 1.6
  ; Individual phase for each voice.
  kphas phasorbnk kspeed * 0.7, kindex, icnt
  klfo table kphas, giwave, 1
  ; Arbitrary parameter twiddling...
  kdepth pow 1.4, kindex
  kfreq pow kindex + 1, 1.5
  kfreq = kfreq + klfo*0.006*kdepth

  ; Write freqs to table for adsynt.
  tablew kfreq, kindex, gifrqs 

  ; Generate lfo for amplitudes.
  kspeed  pow kindex + 1, 0.8
  ; Individual phase for each voice.
  kphas phasorbnk kspeed*0.13, kindex, icnt, 2
  klfo table kphas, giwave, 1
  ; Arbitrary parameter twiddling...
  kamp pow 1 / (kindex + 1), 0.4
  kamp = kamp * (0.3+0.35*(klfo+1))

  ; Write amps to table for adsynt.
  tablew kamp, kindex, giamps

  kindex = kindex + 1
  ; Do loop.
  if (kindex < icnt) kgoto loop

  asig adsynt 0.25, 150, giwave, gifrqs, giamps, icnt
  outs asig, asig
endin


</CsInstruments>
<CsScore>

; Play Instrument #1 for 2.5 seconds.
i 1 0 2.5
; Play Instrument #2 for 2.5 seconds.
i 2 3 2.5
e


</CsScore>
</CsoundSynthesizer>

See also

Additive Synthesis/Resynthesis

Credits

Author: Peter Neubäcker
Munich, Germany
August, 1999

New in Csound version 3.58