Skip to content

chnclear

Clears a number of audio output channel of the named software bus.

Implies declaring the channel with imode=2 (see also chn_a).

Syntax

chnclear(Sname1[, Sname2,...])

chnclear Sname1[, Sname2,...]

Initialization

Sname* -- a string that indicates which named channel of the software bus to clear.

Examples

Here is an example of the chnclear opcode. It uses the file chnclear-modern.csd.

Example of the chnclear opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o chnclear.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>
;Example by Joachim Heintz
sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1; send i-values
  chnset(1, "sio")
  chnset(-1, "non")
endin

instr 2; send k-values
  freq:k = randomi(100, 300, 1)
  chnset(freq, "cntrfreq")
  bw:k = freq/10
  chnset(bw, "bandw")
endin

instr 3; send a-values
  nois:a = rand(0.1)
  chnset(nois, "noise")
loop:
  dur:i = random(0.3, 1.5)
  timout(0, dur, do_)
  reinit(loop)
do_:
  freq:i = random(400, 1200)
  amp:i = random(0.1, 0.3)
  sig:a = oscils(amp, freq, 0)
  env:a = transeg(1, dur, -10, 0)
  sine:a = sig * env
  chnset(sine, "sine")
endin

instr 11; receive some chn values and send again
  val1:i = chnget("sio")
  val2:i = chnget("non")
  print(val1, val2)
  cntfreq:k = chnget("cntrfreq")
  bandw:k = chnget("bandw")
  nois:a = chnget("noise")
  filt:a = reson(nois, cntfreq, bandw)
  filt = balance(filt, nois)
  chnset(filt, "filtered")
endin

instr 12; mix the two audio signals
  mix1:a = chnget("sine")
  mix2:a = chnget("filtered")
  chnmix(mix1, "mix")
  chnmix(mix2, "mix")
endin

instr 20; receive and reverb
  mix:a = chnget("mix")
  aL, aR = freeverb(mix, mix, 0.8, 0.5)
  outs(aL, aR)
endin

instr 100; clear
  chnclear("mix")
endin

</CsInstruments>
<CsScore>
i 1 0 20
i 2 0 20
i 3 0 20
i 11 0 20
i 12 0 20
i 20 0 20
i 100 0 20
</CsScore>
</CsoundSynthesizer>

Here is an example of the chnclear opcode. It uses the file chnclear.csd.

Example of the chnclear opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o chnclear.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>
;Example by Joachim Heintz
sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

  instr 1; send i-values
          chnset    1, "sio"
          chnset    -1, "non"
  endin

  instr 2; send k-values
kfreq     randomi   100, 300, 1
          chnset    kfreq, "cntrfreq"
kbw       =         kfreq/10
          chnset    kbw, "bandw"
  endin

  instr 3; send a-values
anois     rand      .1
          chnset    anois, "noise"
 loop:
idur      random    .3, 1.5
          timout    0, idur, do_
          reinit    loop
 do_:
ifreq     random    400, 1200
iamp      random    .1, .3
asig      oscils    iamp, ifreq, 0
aenv      transeg   1, idur, -10, 0
asine     =         asig * aenv
          chnset    asine, "sine"
  endin

  instr 11; receive some chn values and send again
ival1     chnget    "sio"
ival2     chnget    "non"
          print     ival1, ival2
kcntfreq  chnget    "cntrfreq"
kbandw    chnget    "bandw"
anoise    chnget    "noise"
afilt     reson     anoise, kcntfreq, kbandw
afilt     balance   afilt, anoise
          chnset    afilt, "filtered"
  endin

  instr 12; mix the two audio signals
amix1     chnget     "sine"
amix2     chnget     "filtered"
          chnmix     amix1, "mix"
          chnmix     amix2, "mix"
  endin

  instr 20; receive and reverb
amix      chnget     "mix"
aL, aR    freeverb   amix, amix, .8, .5
          outs       aL, aR
  endin

  instr 100; clear
          chnclear   "mix"
  endin

</CsInstruments>
<CsScore>
i 1 0 20
i 2 0 20
i 3 0 20
i 11 0 20
i 12 0 20
i 20 0 20
i 100 0 20
</CsScore>
</CsoundSynthesizer>

See also

Software Bus

Credits

Author: Istvan Varga
2006