Skip to content

genarrayi

Generate a vector (one-dimensional k-rate) with an arithmetic sequence at initialisation time.

Syntax

karray = genarrayi(istart, iend [,inc])

karray genarray_i istart, iend [,inc]

Initialization

istart -- value to place in first element.

iend -- last value to place in array.

inc -- amount to add to previous value (default 1).

Examples

Here is an example of the genarrayi opcode. It uses the file genarrayi.csd.

Example of the genarrayi opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1
  ;create and fill two arrays
  Arr1:k[] = genarrayi(1, 6)
  Arr2:k[] = genarrayi(1, 6, 2/3)

  ;print the content of kArr1
  printf("%s", 1, "kArr1: start=1, end=6, step=default\n")
  ndx:k = 0
  until ndx == lenarray(Arr1) do
    printf("Arr1[%d] = %f\n", ndx+1, ndx, Arr1[ndx])
    ndx += 1
  od

  ;print the content of kArr2
  printf("%s", 1, "Arr2: start=1, end=6, step=2/3\n")
  ndx = 0
  until ndx == lenarray(Arr2) do
    printf("Arr2[%d] = %f\n", ndx+1, ndx, Arr2[ndx])
    ndx += 1
  od

  turnoff()
endin

</CsInstruments>
<CsScore>
i 1 0 1
</CsScore>
</CsoundSynthesizer>

Here is an example of the genarray_i opcode. It uses the file genarray_i.csd.

Example of the genarray_i opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

;create and fill two arrays
kArr1[] genarray_i 1, 6
kArr2[] genarray_i 1, 6, 2/3

;print the content of kArr1
        printf  "%s", 1, "kArr1: start=1, end=6, step=default\n"
kndx    =       0
  until kndx == lenarray(kArr1) do
        printf  "kArr[%d] = %f\n", kndx+1, kndx, kArr1[kndx]
kndx    +=      1
  od

;print the content of kArr2
        printf  "%s", 1, "kArr2: start=1, end=6, step=2/3\n"
kndx    =       0
  until kndx == lenarray(kArr2) do
        printf  "kArr[%d] = %f\n", kndx+1, kndx, kArr2[kndx]
kndx    +=      1
  od

        turnoff
endin

</CsInstruments>
<CsScore>
i 1 0 1
</CsScore>
</CsoundSynthesizer>

See Also

Array opcodes

Credits

Author: John ffitch
Codemist Ltd
2013

New in version 6.00