mandol

An emulation of a mandolin.

Syntax

ModernClassic

ares = mandol(kamp, kfreq, kpluck, kdetune, kgain, ksize \
              [, ifn] [, iminfreq])

ares mandol kamp, kfreq, kpluck, kdetune, kgain, ksize \
            [, ifn] [, iminfreq]

Initialization

ifn -- table number containing the pluck wave form. The file mandpluk.aiff is suitable for this. It is also available at ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

iminfreq (optional, default=0) -- Lowest frequency to be played on the note. If it is omitted it is taken to be the same as the initial kfreq.

Performance

kamp -- Amplitude of note.

kfreq -- Frequency of note played.

kpluck -- The pluck position, in range 0 to 1. Suggest 0.4.

_kdetune _ -- The proportional detuning between the two strings. Suggested range 0.9 to 1.

kgain -- the loop gain of the model, in the range 0.97 to 1.

ksize -- The size of the body of the mandolin. Range 0 to 2.

Examples

Here is an example of the mandol opcode. It uses the file mandol.csd, and mandpluk.aiff.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o mandol.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kamp    = p4
ksize   = p5
kdetune = p6
asig mandol kamp, 880, .4, kdetune, 0.99, ksize, 1, 220
     outs asig, asig

endin
</CsInstruments>
<CsScore>
; "mandpluk.aiff" audio file
f 1 0 8192 1 "mandpluk.aiff" 0 0 0

i 1 .5 1  1  2 .99
i 1 +  1 .5  1 .99      ;lower volume to compensate
i 1 +  3 .3 .3 .99      ;lower volume to compensate

i 1 4  1  1  2 .39      ;change detune value
i 1 +  1 .5  1 .39
i 1 +  3 .3 .3 .39
e
</CsScore>
</CsoundSynthesizer>

See Also

Models and Emulations

Credits

Author: John ffitch (after Perry Cook)
University of Bath, Codemist Ltd.
Bath, UK

New in Csound version 3.47