Skip to content

|

Bitwise OR operator.

The bitwise operators perform operations of bitwise AND, bitwise OR, bitwise NOT and bitwise non-equivalence.

Syntax

a | b  (bitwise OR)

where the arguments \(a\) and \(b\) may be further expressions. They are converted to the nearest integer to machine precision and then the operation is performed.

Performance

The priority of these operators is less binding that the arithmetic ones, but more binding that the comparisons.

Parentheses may be used as above to force particular groupings.

Examples

Here is an example of the bitwise AND and OR operators. It uses the file bitwise-modern.csd.

Example of the bitwise operators.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
<CsoundSynthesizer>
<CsOptions>
-n
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2

instr 1
  resultOr:i = p4 | p5
  resultAnd:i = p4 & p5
  prints("%i | %i  = %i\\n", p4, p5, resultOr)
  prints("%i & %i  = %i\\n", p4, p5, resultAnd)
endin


instr 2 ; decimal to binary converter
  binary:S = ""
  numbits:i = 8
  Count:i = init(numbits - 1)

  while Count >= 0 do
    value:i = 2 ^ Count
    if (p4 & value) == value then
      digit:S = "1"
    else
      digit = "0"
    endif
    binary:S = strcat(binary, digit)
    Count -= 1
  od

  text:S = sprintf("%i is %s in binary\\n", p4, binary)
  prints(text)
endin

</CsInstruments>
<CsScore>
i 1 0 0.1  1  2
i 1 +  .   1  3
i 1 +  .   2  4
i 1 +  .   3  10

i 2 2 0.1  12
i 2 +  .   9
i 2 +  .   15
i 2 +  .   49

e
</CsScore>
</CsoundSynthesizer>

Here is an example of the bitwise AND and OR operators. It uses the file bitwise.csd.

Example of the bitwise operators.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
<CsoundSynthesizer>
<CsOptions>
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2

instr 1
iresultOr = p4 | p5
iresultAnd = p4 & p5
prints "%i | %i  = %i\\n", p4, p5, iresultOr
prints "%i & %i  = %i\\n", p4, p5, iresultAnd
endin


instr 2 ; decimal to binary converter
Sbinary = ""
inumbits = 8
icount init inumbits - 1

pass:

        ivalue = 2 ^ icount
        if ((p4 & ivalue) >= ivalue) then
                Sdigit = "1"
        else
                Sdigit = "0"
        endif
        Sbinary strcat Sbinary, Sdigit

loop_ge icount, 1, 0, pass

Stext sprintf "%i is %s in binary\\n", p4, Sbinary
prints Stext
endin

</CsInstruments>
<CsScore>
i 1 0 0.1  1  2
i 1 +  .   1  3
i 1 +  .   2  4
i 1 +  .   3  10

i 2 2 0.1   12
i 2 +  .    9
i 2 +  .    15
i 2 +  .    49

e
</CsScore>
</CsoundSynthesizer>

Here is an example for the bitwise-group, comparing the different bitwise opcodes. It uses the file bitwise-group-modern.csd.

Example of the bitwise group.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
<CsoundSynthesizer>
<CsOptions>
--nosound
</CsOptions>
<CsInstruments>

sr     = 44100
ksmps  = 32
nchnls = 2
0dbfs  = 1

; By Daniele Cucchi - 2020

;a & b: bitwise AND
;a | b: bitwise OR
;a # b: bitwise NON EQUIVALENCE - XOR
; ~ a: bitwise NOT

instr 1
  ArrayA:k[] = fillarray(0, 0, 1, 1)  ; Fill array "A" with 4 values: 0, 0, 1, 1
  i0A = i(ArrayA, 0)
  i1A = i(ArrayA, 1)
  i2A = i(ArrayA, 2)
  i3A = i(ArrayA, 3)

  ArrayB:k[] = fillarray(0, 1, 0, 1)  ; Fill array "B" with 4 values: 0, 1, 0, 1
  i0B = i(ArrayB, 0)
  i1B = i(ArrayB, 1)
  i2B = i(ArrayB, 2)
  i3B = i(ArrayB, 3)

  ; Bitwise operations & fill arrays
  AND:k[] = ArrayA & ArrayB
  OR:k[] = ArrayA | ArrayB
  NON:k[] = fillarray(i0B # i0A, i1B # i1A, i2B # i2A, i3B # i3A)
  NOT:k[] = fillarray(~i0A & 1, ~i1A & 1, ~i2A & 1, ~i3A & 1)

  ; Print values 
  printarray(AND, "%d", "= bitwise AND")
  printarray(OR, "%d", "= bitwise OR")
  printarray(NON, "%d", "= bitwise NON")
  printarray(NOT, "%d", "= bitwise NOT")
endin

</CsInstruments>
<CsScore>
i1 0 0.001
e
</CsScore>
</CsoundSynthesizer>

Here is an example for the bitwise-group, comparing the different bitwise opcodes. It uses the file bitwise-group.csd.

Example of the bitwise group.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
<CsoundSynthesizer>
<CsOptions>
--nosound
</CsOptions>
<CsInstruments>

sr     =    44100
ksmps  =    32
nchnls =    2
0dbfs  =    1

; By Daniele Cucchi - 2020

;a & b: bitwise AND
;a | b: bitwise OR
;a # b: bitwise NON EQUIVALENCE - XOR
; ~ a: bitwise NOT

instr 1

kArrayA[] fillarray 0, 0, 1, 1  ; Fill array "A" with 4 values: 0, 0, 1, 1
i0A = i(kArrayA, 0)
i1A = i(kArrayA, 1)
i2A = i(kArrayA, 2)
i3A = i(kArrayA, 3)

kArrayB[] fillarray 0, 1, 0, 1  ; Fill array "B" with 4 values: 0, 1, 0, 1
i0B = i(kArrayB, 0)
i1B = i(kArrayB, 1)
i2B = i(kArrayB, 2)
i3B = i(kArrayB, 3)

; Bitwise operations & fill arrays
kAND[] = kArrayA & kArrayB
kOR[] = kArrayA | kArrayB
kNON[] fillarray i0B # i0A, i1B # i1A, i2B # i2A, i3B # i3A
kNOT[] fillarray  ~ i0A, ~ i1A, ~ i2A, ~ i3A

; Print values 
printarray kAND, "%d", "= bitwise AND"
printarray kOR, "%d", "= bitwise OR"
printarray kNON, "%d", "= bitwise NON"
printarray kNOT, "%d", "= bitwise NOT\n"

endin

</CsInstruments>
<CsScore>
i1 0 1
e
</CsScore>
</CsoundSynthesizer>

See also

Arithmetic and Logic Operations