Skip to content

outleta

Sends an arate signal out from an instrument to a named port.

Plugin opcode in signalflowgraph

Syntax

outleta Sname, asignal

Initialization

Sname -- String name of the outlet port. The name of the outlet is implicitly qualified by the instrument name or number, so it is valid to use the same outlet name in more than one instrument (but not to use the same outlet name twice in one instrument).

Performance

asignal -- audio output signal

During performance, the audio output signal is sent to each instance of an instrument containing an inlet port to which this outlet has been connected using the Examplese>

Here is an example of the outleta opcode. It uses the file outleta.csd.

Example of the outleta opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o outleta.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1 

connect  "1", "Outl", "reverby", "InL" 
connect  "1", "Outr", "reverby", "InR" 

alwayson "reverby", 1

instr 1

aIn diskin2 "fox.wav", 1 
    outleta "Outl", aIn 
    outleta "Outr", aIn 

endin 

instr reverby

aInL   inleta "InL" 
aInR   inleta "InR" 

al, ar reverbsc aInL, aInR, 0.7, 21000 
ifxlev = 0.5 
al     = (aInL*ifxlev)+(al*(1-ifxlev)) 
ar     = (aInR*ifxlev)+(ar*(1-ifxlev)) 
       outs al, ar 

endin 
</CsInstruments>
<CsScore>

i 1 0 3 
e4
</CsScore>
</CsoundSynthesizer>

See also

Signal Flow Graph Opcodes

More information on this opcode: http://www.csoundjournal.com/issue13/signalFlowGraphOpcodes.html, written by Michael Gogins

Credits

By: Michael Gogins 2009