Skip to content

sclagud

Exponential Lag (Deprecated).

Plugin opcode in scugens.

Exponential lag with a smoothing time for up- and down signals. DEPRECATED (renamed as lagud)

Syntax

aout = sclagud(ain, klagup, klagdown [, initialvalue])
kout = sclagud(kin, klagup, klagdown [, initialvalue])

aout sclagud ain, klagup, klagdown [, initialvalue]
kout sclagud kin, klagup, klagdown [, initialvalue]

Initialization

initialvalue If given, sets the internal state. Defaults to the first value passed.

Performance

ain -- input signal

klagup -- 60 dB lag time in seconds for the upgoing signal.

klagdown -- 60 dB lag time in seconds for the downgoing signal.

This is essentially the same as sc_lag except that you can supply a different 60 dB time for when the signal goes up, from when the signal goes down. This is useful for smoothing out control signals, where "fade in" should be different from "fade out".

Examples

Here is an example of the sclagud opcode. It uses the file sclagud.csd.

Example of the sclagud opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
<CsoundSynthesizer>
<CsOptions>
  -o dac
</CsOptions>
<CsInstruments>

sr     = 44100
ksmps  = 128
nchnls = 2
0dbfs  = 1.0

instr 1
  x:k = randh(2, 1)
  x2:k = sclagud(x, 1.0, 0.1, 1)
  printks("x %f  x2 %f\n", 0.1, x, x2)
endin

instr 2
  midis:k[] = fillarray(60, 65, 60, 65, 60)
  len:i = lenarray(midis)
  ndx:k = int(linseg(0, len*2, len-0.00000001))
  midi:k = mtof(midis[ndx])
  freq:a = sclagud(a(midi), 1, 0.1)
  a0 = oscili(0.7, freq)
  freq1:k = sclagud(midi, 1, 0.1)
  a1 = oscili(0.7, freq1)
  out(a0, a1)
endin

</CsInstruments>
<CsScore>
i 1 0 10
i 2 0 12

</CsScore>
</CsoundSynthesizer>

Here is an example of the sc_lagud opcode. It uses the file sc_lagud.csd.

Example of the sc_lagud opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
<CsoundSynthesizer>
<CsOptions>
  -o dac
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 128
nchnls = 2
0dbfs = 1.0

instr 1
  kx = randh(2, 1)
  kx2 = sc_lagud(kx, 1.0, 0.1, 1)
  printks "x %f  x2 %f\n", 0.1, kx, kx2
endin

instr 2
  kmidis[] fillarray 60, 65, 60, 65, 60
  ilen = lenarray(kmidis)
  kidx = int(linseg(0, ilen*2, ilen-0.00000001))
  kmidi = mtof(kmidis[kidx])
  afreq = sc_lagud(a(kmidi), 1, 0.1)
  a0 = oscili(0.7, afreq)
  kfreq = sc_lagud(kmidi, 1, 0.1)
  a1 = oscili(0.7, kfreq)
  outch 1, a0
  outch 2, a1
endin

</CsInstruments>
<CsScore>
i 1 0 10
i 2 0 12

</CsScore>
</CsoundSynthesizer>

See also

Standard Filters: Control signal filters

Credits

By: Eduardo Moguillansky 2017