Skip to content

strchar

Return the ASCII code of the character in Sstr at ipos (defaults to zero which means the first character), or zero if ipos is out of range.

strchar runs at init time only.

Syntax

ichr strchar Sstr [, ipos]

Examples

Here is an example of the strchar opcode. It uses the file strchar.csd.

Example of the strchar opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
<CsoundSynthesizer>
<CsOptions>
-ndm0
</CsOptions>
<CsInstruments>
;example by joachim heintz 2013

  opcode ToAscii, S, S                          ;returns the ASCII numbers of the input string as string

Sin        xin                                  ;input string
ilen       strlen     Sin                       ;its length
ipos       =          0                         ;set counter to zero
Sres       =          ""                        ;initialize output string
loop:                                           ;for all characters in input string:
ichr       strchar    Sin, ipos                 ;get its ascii code number
Snew       sprintf    "%d ", ichr               ;put this number into a new string
Sres       strcat     Sres, Snew                ;append this to the output string
           loop_lt    ipos, 1, ilen, loop       ;see comment for 'loop:'
           xout       Sres                      ;return output string
  endop

  instr Characters

printf_i "\nCharacters:\n  given as single strings: %s%s%s%s%s%s\n", 1, "c", "s", "o", "u", "n", "d"
printf_i "  but can also be given as numbers: %c%c%c%c%c%c\n", 1, 99, 115, 111, 117, 110, 100 
Scsound ToAscii "csound"
printf_i "  in csound, the ASCII code of a character can be accessed with the opcode strchar.%s", 1, "\n"
printf_i "  the name 'csound' returns the numbers %s\n\n", 1, Scsound
  endin

</CsInstruments>
<CsScore>

i "Characters" 0 0
e
</CsScore>
</CsoundSynthesizer>

See Also

String Conversion Opcodes

Credits

Author: Istvan Varga
2006