Skip to content

strlower

Convert Ssrc to lower case, and write the result to Sdst.

strlower runs at init time only.

Syntax

Sdst = strlower(Ssrc)

Sdst strlower Ssrc

Examples

Here is an example of the strlower opcode. It uses the file strlower.csd.

Example of the strlower opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n    ;;;no sound output
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
</CsOptions>
<CsInstruments>
;example of Joachim Heintz

  opcode FilSuf, S, So
  ;returns the suffix of a filename or path, optional in lower case 
Spath,ilow xin
ipos   strrindex Spath, "."     ;look for the rightmost '.'
Suf    strsub    Spath, ipos+1  ;extract the substring after "."
 if ilow != 0 then              ;if ilow input is not 0 then 
Suf    strlower  Suf            ;convert to lower case
 endif
       xout      Suf
  endop

instr suff

ilow = p4
       prints    "Printing suffix:\n"
Suf    FilSuf    "/my/dir/my/file.WAV", ilow
       puts      Suf, 1

endin
</CsInstruments>
<CsScore>
i "suff" 0 1 0  ;do not convert to lower case
i "suff" 3 1 1  ;convert to lower case
e
</CsScore>
</CsoundSynthesizer>

See Also

String Conversion Opcodes

Credits

Author: Istvan Varga
2006

New in version 5.02