Skip to content

turnoff2

Turn off instance(s) of other instruments at performance time.

📝 Note

Up to Csound 6, turnoff2i was called turnoff2_i.

Syntax

turnoff2(kinsno, kmode, krelease)
turnoff2i(insno, imode, irelease)

turnoff2 kinsno, kmode, krelease
turnoff2_i insno, imode, irelease

Initialization

insno -- instrument to be turned off (can be fractional) if zero or negative, no instrument is turned off

imode -- sum of the following values:

  • 0, 1, or 2: turn off all instances (0), oldest only (1), or newest only (2)
  • 4: only turn off notes with exactly matching (fractional) instrument number, rather than ignoring fractional part
  • 8: only turn off notes with indefinite duration (p3 < 0 or MIDI)

irelease -- if non-zero, the turned off instances are allowed to release, otherwise are deactivated immediately (possibly resulting in clicks)

Performance

kinsno -- instrument to be turned off (can be fractional) if zero or negative, no instrument is turned off

kmode -- sum of the following values:

  • 0, 1, or 2: turn off all instances (0), oldest only (1), or newest only (2)
  • 4: only turn off notes with exactly matching (fractional) instrument number, rather than ignoring fractional part
  • 8: only turn off notes with indefinite duration (p3 < 0 or MIDI)

krelease -- if non-zero, the turned off instances are allowed to release, otherwise are deactivated immediately (possibly resulting in clicks)

📝 Note

As a rule of thumb, you should turn off instruments with a higher instrument number than the one where turnoff is called, as doing otherwise might cause initialization issues.

Examples

Here is an example of the turnoff2 opcode. It uses the file turnoff2-modern.csd.

Example of the turnoff2 opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o turnoff2.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr      = 44100    ;samples per second for sound
ksmps   = 32
nchnls  = 2
0dbfs   = 1

; example by Lou Cohen

sine@global:i = ftgen(1, 0, 131073, 9, 1, 1, 0)                ;single sine tone

;-----------------------------------------
instr 2 ;start
  Trigger:k = init(0)
  if Trigger == 0 then
    Multiple:k = 1.1
    Hz:k = 440
    Amp:k = (0dbfs/10)
    ;startup four instances of instrument 200
    event("i", 200, 0, 3000, Amp, Hz)
    Amp *= 0.75
    Hz *= Multiple
    event("i", 200, 0, 3000, Amp, Hz)
    Amp *= 0.75
    Hz *= Multiple
    event("i", 200, 0, 3000, Amp, Hz)
    Amp *= 0.75
    Hz *= Multiple
    event("i", 200, 0, 3000, Amp, Hz)
    Amp *= 0.75
    Hz *= Multiple
    Trigger = 1
  endif
endin
;---------------------------------------------
instr 3 ;after 10 seconds, turn off the instruments
  Trigger:k = init(1)
  if Trigger ==1 then
    turnoff2(200, 1, 1)       ;turn off most recently started instrument instance
    Active:k = active(200)    ;find out how many are still active
    printk2(Active)           ;print mainly to show progress
    turnoff2(200, 0, 1)       ;turn off all the rest of the instruments
    Active = active(200)      ;find out how many are still active
    printk2(Active, 10)       ;print to show progress
  endif
endin
;----------------------------------------------------
instr 200 ;play the tone
  Env:k = linen(1, 0.1, p3, 0.1)
  ar = oscil(Env*p4, p5, sine)
  out(ar, ar)
  print(p4, p5)
endin
</CsInstruments>
<CsScore>
i2 0 0.1 
i3 10 0.1
</CsScore>
</CsoundSynthesizer>

Here is an example of the turnoff2 opcode. It uses the file turnoff2.csd.

Example of the turnoff2 opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o turnoff2.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr      = 44100    ;samples per second for sound
ksmps   = 32
nchnls  = 2
0dbfs   = 1

; example by Lou Cohen

gisine    ftgen    1, 0, 131073, 9, 1, 1, 0                ;single sine tone

;-----------------------------------------
instr 2 ;start
    ktrigger        init        0
    if (ktrigger = 0) then
        kMultiple    =    1.1
        kHz            =    440
        kAmp            =    (0dbfs/10)
;startup four instances of instrument 200
        event    "i", 200, 0, 3000, kAmp, kHz
        kAmp    =    kAmp * 0.75
        kHz    =    kHz * kMultiple
        event    "i", 200, 0, 3000, kAmp, kHz
        kAmp    =    kAmp * 0.75
        kHz    =    kHz * kMultiple
        event    "i", 200, 0, 3000, kAmp, kHz
        kAmp    =    kAmp * 0.75
        kHz    =    kHz * kMultiple
        event    "i", 200, 0, 3000, kAmp, kHz
        kAmp    =    kAmp * 0.75
        kHz    =    kHz * kMultiple
        ktrigger        =    1
    endif
endin
;---------------------------------------------
instr 3 ;after 10 seconds, turn off the instruments
    ktrigger init 1
   if (ktrigger==1) then
        turnoff2 200, 1, 1       ;turn off most recently started instrument instance
        kactive active 200       ;find out how many are still active
        printk2 kactive          ;print mainly to show progress
        turnoff2    200, 0, 1    ;turn off all the rest of the instruments
        kactive    active 200    ;find out how many are still active
        printk2    kactive, 10   ;print to show progress
endif
endin
;----------------------------------------------------
instr 200 ;play the tone
kEnv    linen    1, 0.1, p3, 0.1
ar      oscil    kEnv*p4, p5, 1
        outs     ar, ar
        print    p4, p5
endin
</CsInstruments>
<CsScore>
i2 0 0.1 
i3 10 0.1
</CsScore>
</CsoundSynthesizer>

See also

Duration Control Statements

Credits

Author: Istvan Varga
2005

New in Csound 5.00