vmulti

Multiplies a vector in a table by a scalar value.

Note

Up to Csound 6, this opcode was called vmult_i.

Syntax

ModernClassic

vmulti(ifn, ival, ielements [, idstoffset])

vmult_i ifn, ival, ielements [, idstoffset]

Initialization

ifn - number of the table hosting the vectorial signal to be processed

ival - scalar value to be multiplied

ielements - number of elements of the vector

idstoffset - index offset for the destination table

Performance

vmulti multiplies each element of the vector contained in the table ifn by ival, starting from table index idstoffset. This enables you to process a specific section of a table by specifying the offset and the number of elements to be processed. Offset is counted starting from 0, so if no offset is specified (or set to 0), the table will be modified from the beginning.

This opcode runs only on initialization, there is a k-rate version of this opcode called vmult.

Negative values for idstoffset are valid. Elements from the vector that are outside the table, will be discarded, and they will not wrap around the table.

In all these opcodes, the resulting vectors are stored in ifn, overriding the intial vectors. If you want to keep initial vector, use vcopy or vcopyi to copy it in another table. All these operators are designed to be used together with other opcodes that operate with vectorial signals such as , vcella, adsynt, adsynt2, etc. They can also be useful in conjunction with the spectral opcodes pvsftw and pvsftr.

Examples

ModernClassic

Here is an example of the vmulti opcode. It uses the file vmulti.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o cigoto.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr     = 44100
ksmps  = 128
nchnls = 2

instr 1
  fn1:i = p4
  val:i = p5
  elements:i = p6
  dstoffset:i = p7
  vmulti(fn1, val, elements, dstoffset)
endin

instr 2 ; Print table
  Table:i = p4
  size:i = ftlen(Table)
  Count:k = init(0)
  val:k = table(Count, Table)
  printk2(val)

  if Count == size then
    turnoff()
  endif

  Count += 1 
endin

</CsInstruments>

<CsScore>

f 1 0 16 -7 1 16 17

i2  0.0  0.2   1
i1  0.4  0.01  1   2      3    4
i2  0.8  0.2   1
i1  1.0  0.01  1   0.5    5   -3
i2  1.2  0.2   1
i1  1.4  0.01  1   1.5   10   12
i2  1.6  0.2   1
e

</CsScore>

</CsoundSynthesizer>

Here is an example of the vmult_i opcode. It uses the file vmult_i.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o cigoto.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr=44100
ksmps=128
nchnls=2

        instr 1
ifn1 = p4
ival = p5
ielements = p6
idstoffset = p7
vmult_i ifn1, ival, ielements, idstoffset
        endin

        instr 2 ;Printtable
itable = p4
isize = ftlen(itable)
kcount init 0
kval table kcount, itable
printk2 kval

if (kcount == isize) then
  turnoff
endif

kcount = kcount + 1 
        endin


</CsInstruments>

<CsScore>

f 1 0 16 -7 1 16 17

i2      0.0     0.2     1
i1      0.4     0.01    1       2       3       4
i2      0.8     0.2     1
i1      1.0     0.01    1       0.5     5       -3
i2      1.2     0.2     1
i1      1.4     0.01    1       1.5     10      12
i2      1.6     0.2     1
e

</CsScore>

</CsoundSynthesizer>

See also

Operations Vectorial/Scalar Signal

Credits

Written by Gabriel Maldonado. Optional arguments added by Andres Cabrera and Istvan Varga.

Example by Andres Cabrera.

New in Csound 5 (Previously available only on CsoundAV)