Skip to content

wterrain

A simple wave-terrain synthesis opcode.

Syntax

aout = wterrain(kamp, kpch, k_xcenter, k_ycenter, k_xradius, k_yradius, \
                itabx, itaby)

aout wterrain kamp, kpch, k_xcenter, k_ycenter, k_xradius, k_yradius, \
              itabx, itaby

Initialization

itabx, itaby -- The two tables that define the terrain.

Performance

The output is the result of drawing an ellipse with axes k_xradius and k_yradius centered at (k_xcenter, k_ycenter), and traversing it at frequency kpch.

Examples

Here is an example of the wterrain opcode. It uses the file wterrain.csd.

Example of the wterrain opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   No messages
-odac           -d     ;;;RT audio out
; For Non-realtime ouput leave only the line below:
; -o wterrain.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kdclk   linseg  0, 0.01, 1, p3-0.02, 1, 0.01, 0
kcx     line    0.1, p3, 1.9
krx     linseg  0.1, p3/2, 0.5, p3/2, 0.1
kpch    line    cpspch(p4), p3, p5 * cpspch(p4)
a1      wterrain    .5, kpch, kcx, kcx, -krx, krx, p6, p7
a1      dcblock a1
outs    a1*kdclk, a1*kdclk

endin


</CsInstruments>
<CsScore>
f1      0       8192    10      1 0 0.33 0 0.2 0 0.14 0 0.11
f2      0       4096    10      1

i1      0       4       7.00 1 1 1
i1      4       4       6.07 1 1 2
i1      8       8       6.00 1 2 2
e
</CsScore>
</CsoundSynthesizer>

See Also

Wave Terrain Synthesis

Credits

Author: Matthew Gillard
New in version 4.19