Description

Modifie un signal par différentiation.

Syntaxe

ares diff asig [, iskip]

kres diff ksig [, iskip]

Initialisation

iskip (facultatif) -- état initial de l'espace mémoire interne (voir reson). La valeur par défaut est 0.

Exécution

integ et diff réalisent l'intégration et la différentiation d'un signal de contrôle ou audio en entrée. Ils sont mutuellement inverses et l'application des deux reconstruit le signal original. Comme ces unités sont des cas particuliers de filtres passe-bas et passe-haut, ils produisent une sortie pondérée (et modifiée en phase) en fonction de la fréquence. Ainsi diff d'un sinus produit un cosinus dont l'amplitude vaut 2 * pi * Hz / sr de l'original (pour chaque partiel) ; integ affectera inversement les amplitudes de ses composants en entrée. Sachant cela, ces unités peuvent fournir d'utiles modifications de signal.

Exemples

Voici un exemple de l'opcode diff. Il utilise le fichier diff.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o diff.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1

asig diskin2 "fox.wav", 1
     outs asig, asig

endin

instr 2	; with diff

asig diskin2 "fox.wav", 1
ares diff asig
     outs ares, ares

endin

instr 3	; with integ

asig diskin2 "fox.wav", 1
aint integ asig
aint = aint*.05			;way too loud
     outs aint, aint

endin

instr 4	; with diff and integ

asig diskin2 "fox.wav", 1
ares diff asig
aint integ ares
     outs aint, aint

endin

</CsInstruments>
<CsScore>

i 1 0 1
i 2 1 1
i 3 2 1
i 4 3 1

e

</CsScore>
</CsoundSynthesizer>

Voir aussi

downsamp, integ, interp, samphold, upsamp