Description

Retourne la longueur d'un fichier son.

Syntaxe

ir filelen ifilcod, [iallowraw]

Initialisation

ifilcod -- fichier son à interroger

iallowraw -- (facultatif) permet des fichiers son bruts (vaut 1 par défaut)

Exécution

filelen retourne la longueur du fichier son ifilcod en secondes. filelen peut retourner la longueur des fichiers de type convolve et PVOC si le paramètre iallowraw est différent de zéro (il est non nul par défaut).

Exemples

Voici un exemple de l'opcode filelen. Il utilise les fichiers filelen.csd, fox.wav et drumsSlp.wav.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
; For Non-realtime ouput leave only the line below:
;-o filelen.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; by Menno Knevel 2022

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1 ; choose between mono or stereo file

ilen   filelen p4	      ; calculate length of soundfile
prints "\nlenght of sample = %2.3f seconds\n\n", ilen
ichn filenchnls  p4	      ; check number of channels

if (ichn == 1) then           ; mono signal
     asig diskin2 p4, 1	
     outs    asig, asig
else
     aL, aR diskin2 p4, 1     ; stereo signal 
     outs    aL, aR
endif
endin

</CsInstruments>
<CsScore>

i 1 0 3 "fox.wav"	; mono signal
i 1 5 4 "drumsSlp.wav"	; stereo signal
e
</CsScore>
</CsoundSynthesizer>

Le fichier audio mono « fox.wav » dure environ 2.8 secondes et le fichier stéréo « drumsSlp.wav » dure 4 secondes. Ainsi la sortie de filelen contiendra une ligne pour le fichier mono et pour le fichier stéréo comme ceci :

lenght of sample = 2.757 seconds
lenght of sample = 4.000 seconds

Voir aussi

filebit, filenchnls, filepeak, filesr

Crédits

Nouveau dans la version 3.57 de Csound